Modules

  • ABCDE
  • FGHIL
  • MNOPS
  • TUX

Tools

strict

Perl 5 version 10.0 documentation
Recently read

strict

NAME

strict - Perl pragma to restrict unsafe constructs

SYNOPSIS

  1. use strict;
  2. use strict "vars";
  3. use strict "refs";
  4. use strict "subs";
  5. use strict;
  6. no strict "vars";

DESCRIPTION

If no import list is supplied, all possible restrictions are assumed. (This is the safest mode to operate in, but is sometimes too strict for casual programming.) Currently, there are three possible things to be strict about: "subs", "vars", and "refs".

  • strict refs

    This generates a runtime error if you use symbolic references (see perlref).

    1. use strict 'refs';
    2. $ref = \$foo;
    3. print $$ref; # ok
    4. $ref = "foo";
    5. print $$ref; # runtime error; normally ok
    6. $file = "STDOUT";
    7. print $file "Hi!"; # error; note: no comma after $file

    There is one exception to this rule:

    1. $bar = \&{'foo'};
    2. &$bar;

    is allowed so that goto &$AUTOLOAD would not break under stricture.

  • strict vars

    This generates a compile-time error if you access a variable that wasn't declared via our or use vars , localized via my(), or wasn't fully qualified. Because this is to avoid variable suicide problems and subtle dynamic scoping issues, a merely local() variable isn't good enough. See my and local.

    1. use strict 'vars';
    2. $X::foo = 1; # ok, fully qualified
    3. my $foo = 10; # ok, my() var
    4. local $foo = 9; # blows up
    5. package Cinna;
    6. our $bar; # Declares $bar in current package
    7. $bar = 'HgS'; # ok, global declared via pragma

    The local() generated a compile-time error because you just touched a global name without fully qualifying it.

    Because of their special use by sort(), the variables $a and $b are exempted from this check.

  • strict subs

    This disables the poetry optimization, generating a compile-time error if you try to use a bareword identifier that's not a subroutine, unless it is a simple identifier (no colons) and that it appears in curly braces or on the left hand side of the => symbol.

    1. use strict 'subs';
    2. $SIG{PIPE} = Plumber; # blows up
    3. $SIG{PIPE} = "Plumber"; # just fine: quoted string is always ok
    4. $SIG{PIPE} = \&Plumber; # preferred form

See Pragmatic Modules in perlmodlib.

HISTORY

strict 'subs' , with Perl 5.6.1, erroneously permitted to use an unquoted compound identifier (e.g. Foo::Bar ) as a hash key (before => or inside curlies), but without forcing it always to a literal string.

Starting with Perl 5.8.1 strict is strict about its restrictions: if unknown restrictions are used, the strict pragma will abort with

  1. Unknown 'strict' tag(s) '...'

As of version 1.04 (Perl 5.10), strict verifies that it is used as "strict" to avoid the dreaded Strict trap on case insensitive file systems.