• TUX



Perl 5 version 12.5 documentation
Recently read


NAME - Provide a pseudo-class NEXT (et al) that allows method redispatch


  1. use NEXT;
  2. package A;
  3. sub A::method { print "$_[0]: A method\n"; $_[0]->NEXT::method() }
  4. sub A::DESTROY { print "$_[0]: A dtor\n"; $_[0]->NEXT::DESTROY() }
  5. package B;
  6. use base qw( A );
  7. sub B::AUTOLOAD { print "$_[0]: B AUTOLOAD\n"; $_[0]->NEXT::AUTOLOAD() }
  8. sub B::DESTROY { print "$_[0]: B dtor\n"; $_[0]->NEXT::DESTROY() }
  9. package C;
  10. sub C::method { print "$_[0]: C method\n"; $_[0]->NEXT::method() }
  11. sub C::AUTOLOAD { print "$_[0]: C AUTOLOAD\n"; $_[0]->NEXT::AUTOLOAD() }
  12. sub C::DESTROY { print "$_[0]: C dtor\n"; $_[0]->NEXT::DESTROY() }
  13. package D;
  14. use base qw( B C );
  15. sub D::method { print "$_[0]: D method\n"; $_[0]->NEXT::method() }
  16. sub D::AUTOLOAD { print "$_[0]: D AUTOLOAD\n"; $_[0]->NEXT::AUTOLOAD() }
  17. sub D::DESTROY { print "$_[0]: D dtor\n"; $_[0]->NEXT::DESTROY() }
  18. package main;
  19. my $obj = bless {}, "D";
  20. $obj->method(); # Calls D::method, A::method, C::method
  21. $obj->missing_method(); # Calls D::AUTOLOAD, B::AUTOLOAD, C::AUTOLOAD
  22. # Clean-up calls D::DESTROY, B::DESTROY, A::DESTROY, C::DESTROY

DESCRIPTION adds a pseudoclass named NEXT to any program that uses it. If a method m calls $self->NEXT::m() , the call to m is redispatched as if the calling method had not originally been found.

In other words, a call to $self->NEXT::m() resumes the depth-first, left-to-right search of $self 's class hierarchy that resulted in the original call to m.

Note that this is not the same thing as $self->SUPER::m() , which begins a new dispatch that is restricted to searching the ancestors of the current class. $self->NEXT::m() can backtrack past the current class -- to look for a suitable method in other ancestors of $self -- whereas $self->SUPER::m() cannot.

A typical use would be in the destructors of a class hierarchy, as illustrated in the synopsis above. Each class in the hierarchy has a DESTROY method that performs some class-specific action and then redispatches the call up the hierarchy. As a result, when an object of class D is destroyed, the destructors of all its parent classes are called (in depth-first, left-to-right order).

Another typical use of redispatch would be in AUTOLOAD 'ed methods. If such a method determined that it was not able to handle a particular call, it might choose to redispatch that call, in the hope that some other AUTOLOAD (above it, or to its left) might do better.

By default, if a redispatch attempt fails to find another method elsewhere in the objects class hierarchy, it quietly gives up and does nothing (but see Enforcing redispatch). This gracious acquiescence is also unlike the (generally annoying) behaviour of SUPER , which throws an exception if it cannot redispatch.

Note that it is a fatal error for any method (including AUTOLOAD ) to attempt to redispatch any method that does not have the same name. For example:

  1. sub D::oops { print "oops!\n"; $_[0]->NEXT::other_method() }

Enforcing redispatch

It is possible to make NEXT redispatch more demandingly (i.e. like SUPER does), so that the redispatch throws an exception if it cannot find a "next" method to call.

To do this, simple invoke the redispatch as:

  1. $self->NEXT::ACTUAL::method();

rather than:

  1. $self->NEXT::method();

The ACTUAL tells NEXT that there must actually be a next method to call, or it should throw an exception.

NEXT::ACTUAL is most commonly used in AUTOLOAD methods, as a means to decline an AUTOLOAD request, but preserve the normal exception-on-failure semantics:

  1. sub AUTOLOAD {
  2. if ($AUTOLOAD =~ /foo|bar/) {
  3. # handle here
  4. }
  5. else { # try elsewhere
  6. shift()->NEXT::ACTUAL::AUTOLOAD(@_);
  7. }
  8. }

By using NEXT::ACTUAL , if there is no other AUTOLOAD to handle the method call, an exception will be thrown (as usually happens in the absence of a suitable AUTOLOAD ).

Avoiding repetitions

If NEXT redispatching is used in the methods of a "diamond" class hierarchy:

  1. # A B
  2. # / \ /
  3. # C D
  4. # \ /
  5. # E
  6. use NEXT;
  7. package A;
  8. sub foo { print "called A::foo\n"; shift->NEXT::foo() }
  9. package B;
  10. sub foo { print "called B::foo\n"; shift->NEXT::foo() }
  11. package C; @ISA = qw( A );
  12. sub foo { print "called C::foo\n"; shift->NEXT::foo() }
  13. package D; @ISA = qw(A B);
  14. sub foo { print "called D::foo\n"; shift->NEXT::foo() }
  15. package E; @ISA = qw(C D);
  16. sub foo { print "called E::foo\n"; shift->NEXT::foo() }
  17. E->foo();

then derived classes may (re-)inherit base-class methods through two or more distinct paths (e.g. in the way E inherits A::foo twice -- through C and D ). In such cases, a sequence of NEXT redispatches will invoke the multiply inherited method as many times as it is inherited. For example, the above code prints:

  1. called E::foo
  2. called C::foo
  3. called A::foo
  4. called D::foo
  5. called A::foo
  6. called B::foo

(i.e. A::foo is called twice).

In some cases this may be the desired effect within a diamond hierarchy, but in others (e.g. for destructors) it may be more appropriate to call each method only once during a sequence of redispatches.

To cover such cases, you can redispatch methods via:

  1. $self->NEXT::DISTINCT::method();

rather than:

  1. $self->NEXT::method();

This causes the redispatcher to only visit each distinct method method once. That is, to skip any classes in the hierarchy that it has already visited during redispatch. So, for example, if the previous example were rewritten:

  1. package A;
  2. sub foo { print "called A::foo\n"; shift->NEXT::DISTINCT::foo() }
  3. package B;
  4. sub foo { print "called B::foo\n"; shift->NEXT::DISTINCT::foo() }
  5. package C; @ISA = qw( A );
  6. sub foo { print "called C::foo\n"; shift->NEXT::DISTINCT::foo() }
  7. package D; @ISA = qw(A B);
  8. sub foo { print "called D::foo\n"; shift->NEXT::DISTINCT::foo() }
  9. package E; @ISA = qw(C D);
  10. sub foo { print "called E::foo\n"; shift->NEXT::DISTINCT::foo() }
  11. E->foo();

then it would print:

  1. called E::foo
  2. called C::foo
  3. called A::foo
  4. called D::foo
  5. called B::foo

and omit the second call to A::foo (since it would not be distinct from the first call to A::foo ).

Note that you can also use:

  1. $self->NEXT::DISTINCT::ACTUAL::method();


  1. $self->NEXT::ACTUAL::DISTINCT::method();

to get both unique invocation and exception-on-failure.

Note that, for historical compatibility, you can also use NEXT::UNSEEN instead of NEXT::DISTINCT .

Invoking all versions of a method with a single call

Yet another pseudo-class that provides is EVERY . Its behaviour is considerably simpler than that of the NEXT family. A call to:

  1. $obj->EVERY::foo();

calls every method named foo that the object in $obj has inherited. That is:

  1. use NEXT;
  2. package A; @ISA = qw(B D X);
  3. sub foo { print "A::foo " }
  4. package B; @ISA = qw(D X);
  5. sub foo { print "B::foo " }
  6. package X; @ISA = qw(D);
  7. sub foo { print "X::foo " }
  8. package D;
  9. sub foo { print "D::foo " }
  10. package main;
  11. my $obj = bless {}, 'A';
  12. $obj->EVERY::foo(); # prints" A::foo B::foo X::foo D::foo

Prefixing a method call with EVERY:: causes every method in the object's hierarchy with that name to be invoked. As the above example illustrates, they are not called in Perl's usual "left-most-depth-first" order. Instead, they are called "breadth-first-dependency-wise".

That means that the inheritance tree of the object is traversed breadth-first and the resulting order of classes is used as the sequence in which methods are called. However, that sequence is modified by imposing a rule that the appropriate method of a derived class must be called before the same method of any ancestral class. That's why, in the above example, X::foo is called before D::foo , even though D comes before X in @B::ISA .

In general, there's no need to worry about the order of calls. They will be left-to-right, breadth-first, most-derived-first. This works perfectly for most inherited methods (including destructors), but is inappropriate for some kinds of methods (such as constructors, cloners, debuggers, and initializers) where it's more appropriate that the least-derived methods be called first (as more-derived methods may rely on the behaviour of their "ancestors"). In that case, instead of using the EVERY pseudo-class:

  1. $obj->EVERY::foo(); # prints" A::foo B::foo X::foo D::foo

you can use the EVERY::LAST pseudo-class:

  1. $obj->EVERY::LAST::foo(); # prints" D::foo X::foo B::foo A::foo

which reverses the order of method call.

Whichever version is used, the actual methods are called in the same context (list, scalar, or void) as the original call via EVERY , and return:

  • A hash of array references in list context. Each entry of the hash has the fully qualified method name as its key and a reference to an array containing the method's list-context return values as its value.

  • A reference to a hash of scalar values in scalar context. Each entry of the hash has the fully qualified method name as its key and the method's scalar-context return values as its value.

  • Nothing in void context (obviously).

Using EVERY methods

The typical way to use an EVERY call is to wrap it in another base method, that all classes inherit. For example, to ensure that every destructor an object inherits is actually called (as opposed to just the left-most-depth-first-est one):

  1. package Base;
  2. sub DESTROY { $_[0]->EVERY::Destroy }
  3. package Derived1;
  4. use base 'Base';
  5. sub Destroy {...}
  6. package Derived2;
  7. use base 'Base', 'Derived1';
  8. sub Destroy {...}

et cetera. Every derived class than needs its own clean-up behaviour simply adds its own Destroy method (not a DESTROY method), which the call to EVERY::LAST::Destroy in the inherited destructor then correctly picks up.

Likewise, to create a class hierarchy in which every initializer inherited by a new object is invoked:

  1. package Base;
  2. sub new {
  3. my ($class, %args) = @_;
  4. my $obj = bless {}, $class;
  5. $obj->EVERY::LAST::Init(\%args);
  6. }
  7. package Derived1;
  8. use base 'Base';
  9. sub Init {
  10. my ($argsref) = @_;
  11. ...
  12. }
  13. package Derived2;
  14. use base 'Base', 'Derived1';
  15. sub Init {
  16. my ($argsref) = @_;
  17. ...
  18. }

et cetera. Every derived class than needs some additional initialization behaviour simply adds its own Init method (not a new method), which the call to EVERY::LAST::Init in the inherited constructor then correctly picks up.


Damian Conway (


Because it's a module, not an integral part of the interpreter, has to guess where the surrounding call was found in the method look-up sequence. In the presence of diamond inheritance patterns it occasionally guesses wrong.

It's also too slow (despite caching).

Comment, suggestions, and patches welcome.


  1. Copyright (c) 2000-2001, Damian Conway. All Rights Reserved.
  2. This module is free software. It may be used, redistributed
  3. and/or modified under the same terms as Perl itself.