Manual

Reference

Modules

  • A • B • C • D • E
  • F • G • H • I • L
  • M • N • O • P • S
  • T • U • X

Tools

ExtUtils::Packlist

Perl 5 version 8.8 documentation
Go to top • Download PDF
Show page index • Show recent pages
Recently read

ExtUtils::Packlist

NAME

ExtUtils::Packlist - manage .packlist files

SYNOPSIS

  1.    use ExtUtils::Packlist;
  2.    my ($pl) = ExtUtils::Packlist->new('.packlist');
  3.    $pl->read('/an/old/.packlist');
  4.    my @missing_files = $pl->validate();
  5.    $pl->write('/a/new/.packlist');
  7.    $pl->{'/some/file/name'}++;
  8.       or
  9.    $pl->{'/some/other/file/name'} = { type => 'file',
  10.                                       from => '/some/file' };

DESCRIPTION

ExtUtils::Packlist provides a standard way to manage .packlist files. Functions are provided to read and write .packlist files. The original .packlist format is a simple list of absolute pathnames, one per line. In addition, this package supports an extended format, where as well as a filename each line may contain a list of attributes in the form of a space separated list of key=value pairs. This is used by the installperl script to differentiate between files and links, for example.

USAGE

The hash reference returned by the new() function can be used to examine and modify the contents of the .packlist. Items may be added/deleted from the .packlist by modifying the hash. If the value associated with a hash key is a scalar, the entry written to the .packlist by any subsequent write() will be a simple filename. If the value is a hash, the entry written will be the filename followed by the key=value pairs from the hash. Reading back the .packlist will recreate the original entries.

FUNCTIONS

  • new()

    This takes an optional parameter, the name of a .packlist. If the file exists, it will be opened and the contents of the file will be read. The new() method returns a reference to a hash. This hash holds an entry for each line in the .packlist. In the case of old-style .packlists, the value associated with each key is undef. In the case of new-style .packlists, the value associated with each key is a hash containing the key=value pairs following the filename in the .packlist.

  • read()

    This takes an optional parameter, the name of the .packlist to be read. If no file is specified, the .packlist specified to new() will be read. If the .packlist does not exist, Carp::croak will be called.

  • write()

    This takes an optional parameter, the name of the .packlist to be written. If no file is specified, the .packlist specified to new() will be overwritten.

  • validate()

    This checks that every file listed in the .packlist actually exists. If an argument which evaluates to true is given, any missing files will be removed from the internal hash. The return value is a list of the missing files, which will be empty if they all exist.

  • packlist_file()

    This returns the name of the associated .packlist file

EXAMPLE

Here's modrm , a little utility to cleanly remove an installed module.

  1.     #!/usr/local/bin/perl -w
  3.     use strict;
  4.     use IO::Dir;
  5.     use ExtUtils::Packlist;
  6.     use ExtUtils::Installed;
  8.     sub emptydir($) {
  9. 	my ($dir) = @_;
  10. 	my $dh = IO::Dir->new($dir) || return(0);
  11. 	my @count = $dh->read();
  12. 	$dh->close();
  13. 	return(@count == 2 ? 1 : 0);
  14.     }
  16.     # Find all the installed packages
  17.     print("Finding all installed modules...\n");
  18.     my $installed = ExtUtils::Installed->new();
  20.     foreach my $module (grep(!/^Perl$/, $installed->modules())) {
  21.        my $version = $installed->version($module) || "???";
  22.        print("Found module $module Version $version\n");
  23.        print("Do you want to delete $module? [n] ");
  24.        my $r = <STDIN>; chomp($r);
  25.        if ($r && $r =~ /^y/i) {
  26. 	  # Remove all the files
  27. 	  foreach my $file (sort($installed->files($module))) {
  28. 	     print("rm $file\n");
  29. 	     unlink($file);
  30. 	  }
  31. 	  my $pf = $installed->packlist($module)->packlist_file();
  32. 	  print("rm $pf\n");
  33. 	  unlink($pf);
  34. 	  foreach my $dir (sort($installed->directory_tree($module))) {
  35. 	     if (emptydir($dir)) {
  36. 		print("rmdir $dir\n");
  37. 		rmdir($dir);
  38. 	     }
  39. 	  }
  40.        }
  41.     }

AUTHOR

Alan Burlison <Alan.Burlison@uk.sun.com>

Page index