Manual

Reference

Modules

  • A • B • C • D • E
  • F • G • H • I • L
  • M • N • O • P • S
  • T • U • X

Tools

perlintro

Perl 5 version 8.8 documentation
Go to top • Download PDF
Show page index • Show recent pages
Recently read

perlintro

NAME

perlintro -- a brief introduction and overview of Perl

DESCRIPTION

This document is intended to give you a quick overview of the Perl programming language, along with pointers to further documentation. It is intended as a "bootstrap" guide for those who are new to the language, and provides just enough information for you to be able to read other peoples' Perl and understand roughly what it's doing, or write your own simple scripts.

This introductory document does not aim to be complete. It does not even aim to be entirely accurate. In some cases perfection has been sacrificed in the goal of getting the general idea across. You are strongly advised to follow this introduction with more information from the full Perl manual, the table of contents to which can be found in perltoc.

Throughout this document you'll see references to other parts of the Perl documentation. You can read that documentation using the perldoc command or whatever method you're using to read this document.

What is Perl?

Perl is a general-purpose programming language originally developed for text manipulation and now used for a wide range of tasks including system administration, web development, network programming, GUI development, and more.

The language is intended to be practical (easy to use, efficient, complete) rather than beautiful (tiny, elegant, minimal). Its major features are that it's easy to use, supports both procedural and object-oriented (OO) programming, has powerful built-in support for text processing, and has one of the world's most impressive collections of third-party modules.

Different definitions of Perl are given in perl, perlfaq1 and no doubt other places. From this we can determine that Perl is different things to different people, but that lots of people think it's at least worth writing about.

Running Perl programs

To run a Perl program from the Unix command line:

  1.     perl progname.pl

Alternatively, put this as the first line of your script:

  1.     #!/usr/bin/env perl

... and run the script as /path/to/script.pl. Of course, it'll need to be executable first, so chmod 755 script.pl (under Unix).

For more information, including instructions for other platforms such as Windows and Mac OS, read perlrun.

Basic syntax overview

A Perl script or program consists of one or more statements. These statements are simply written in the script in a straightforward fashion. There is no need to have a main() function or anything of that kind.

Perl statements end in a semi-colon:

  1.     print "Hello, world";

Comments start with a hash symbol and run to the end of the line

  1.     # This is a comment

Whitespace is irrelevant:

  1.     print 
  2.         "Hello, world"
  3.         ;

... except inside quoted strings:

  1.     # this would print with a linebreak in the middle
  2.     print "Hello
  3.         world";

Double quotes or single quotes may be used around literal strings:

  1.     print "Hello, world";
  2.     print 'Hello, world';

However, only double quotes "interpolate" variables and special characters such as newlines (\n ):

  1.     print "Hello, $name\n";     # works fine
  2.     print 'Hello, $name\n';     # prints $name\n literally

Numbers don't need quotes around them:

  1.     print 42;

You can use parentheses for functions' arguments or omit them according to your personal taste. They are only required occasionally to clarify issues of precedence.

  1.     print("Hello, world\n");
  2.     print "Hello, world\n";

More detailed information about Perl syntax can be found in perlsyn.

Perl variable types

Perl has three main variable types: scalars, arrays, and hashes.

  • Scalars

    A scalar represents a single value:

    1.     my $animal = "camel";
    2.     my $answer = 42;

    Scalar values can be strings, integers or floating point numbers, and Perl will automatically convert between them as required. There is no need to pre-declare your variable types.

    Scalar values can be used in various ways:

    1.     print $animal;
    2.     print "The animal is $animal\n";
    3.     print "The square of $answer is ", $answer * $answer, "\n";

    There are a number of "magic" scalars with names that look like punctuation or line noise. These special variables are used for all kinds of purposes, and are documented in perlvar. The only one you need to know about for now is $_ which is the "default variable". It's used as the default argument to a number of functions in Perl, and it's set implicitly by certain looping constructs.

    1.     print;          # prints contents of $_ by default
  • Arrays

    An array represents a list of values:

    1.     my @animals = ("camel", "llama", "owl");
    2.     my @numbers = (23, 42, 69);
    3.     my @mixed   = ("camel", 42, 1.23);

    Arrays are zero-indexed. Here's how you get at elements in an array:

    1.     print $animals[0];              # prints "camel"
    2.     print $animals[1];              # prints "llama"

    The special variable $#array tells you the index of the last element of an array:

    1.     print $mixed[$#mixed];       # last element, prints 1.23

    You might be tempted to use $#array + 1 to tell you how many items there are in an array. Don't bother. As it happens, using @array where Perl expects to find a scalar value ("in scalar context") will give you the number of elements in the array:

    1.     if (@animals < 5) { ... }

    The elements we're getting from the array start with a $ because we're getting just a single value out of the array -- you ask for a scalar, you get a scalar.

    To get multiple values from an array:

    1.     @animals[0,1];                  # gives ("camel", "llama");
    2.     @animals[0..2];                 # gives ("camel", "llama", "owl");
    3.     @animals[1..$#animals];         # gives all except the first element

    This is called an "array slice".

    You can do various useful things to lists:

    1.     my @sorted    = sort @animals;
    2.     my @backwards = reverse @numbers;

    There are a couple of special arrays too, such as @ARGV (the command line arguments to your script) and @_ (the arguments passed to a subroutine). These are documented in perlvar.

  • Hashes

    A hash represents a set of key/value pairs:

    1.     my %fruit_color = ("apple", "red", "banana", "yellow");

    You can use whitespace and the => operator to lay them out more nicely:

    1.     my %fruit_color = (
    2.         apple  => "red",
    3.         banana => "yellow",
    4.     );

    To get at hash elements:

    1.     $fruit_color{"apple"};           # gives "red"

    You can get at lists of keys and values with keys() and values().

    1.     my @fruits = keys %fruit_colors;
    2.     my @colors = values %fruit_colors;

    Hashes have no particular internal order, though you can sort the keys and loop through them.

    Just like special scalars and arrays, there are also special hashes. The most well known of these is %ENV which contains environment variables. Read all about it (and other special variables) in perlvar.

Scalars, arrays and hashes are documented more fully in perldata.

More complex data types can be constructed using references, which allow you to build lists and hashes within lists and hashes.

A reference is a scalar value and can refer to any other Perl data type. So by storing a reference as the value of an array or hash element, you can easily create lists and hashes within lists and hashes. The following example shows a 2 level hash of hash structure using anonymous hash references.

  1.     my $variables = {
  2.         scalar  =>  { 
  3.                      description => "single item",
  4.                      sigil => '$',
  5.                     },
  6.         array   =>  {
  7.                      description => "ordered list of items",
  8.                      sigil => '@',
  9.                     },
  10.         hash    =>  {
  11.                      description => "key/value pairs",
  12.                      sigil => '%',
  13.                     },
  14.     };
  16.     print "Scalars begin with a $variables->{'scalar'}->{'sigil'}\n";

Exhaustive information on the topic of references can be found in perlreftut, perllol, perlref and perldsc.

Variable scoping

Throughout the previous section all the examples have used the syntax:

  1.     my $var = "value";

The my is actually not required; you could just use:

  1.     $var = "value";

However, the above usage will create global variables throughout your program, which is bad programming practice. my creates lexically scoped variables instead. The variables are scoped to the block (i.e. a bunch of statements surrounded by curly-braces) in which they are defined.

  1.     my $a = "foo";
  2.     if ($some_condition) {
  3.         my $b = "bar";
  4.         print $a;           # prints "foo"
  5.         print $b;           # prints "bar"
  6.     }
  7.     print $a;               # prints "foo"
  8.     print $b;               # prints nothing; $b has fallen out of scope

Using my in combination with a use strict; at the top of your Perl scripts means that the interpreter will pick up certain common programming errors. For instance, in the example above, the final print $b would cause a compile-time error and prevent you from running the program. Using strict is highly recommended.

Conditional and looping constructs

Perl has most of the usual conditional and looping constructs except for case/switch (but if you really want it, there is a Switch module in Perl 5.8 and newer, and on CPAN. See the section on modules, below, for more information about modules and CPAN).

The conditions can be any Perl expression. See the list of operators in the next section for information on comparison and boolean logic operators, which are commonly used in conditional statements.

  • if 
    1.     if ( condition ) {
    2.         ...
    3.     } elsif ( other condition ) {
    4.         ...
    5.     } else {
    6.         ...
    7.     }

    There's also a negated version of it:

    1.     unless ( condition ) {
    2.         ...
    3.     }

    This is provided as a more readable version of if (!<i>condition</i>).

    Note that the braces are required in Perl, even if you've only got one line in the block. However, there is a clever way of making your one-line conditional blocks more English like:

    1.     # the traditional way
    2.     if ($zippy) {
    3.         print "Yow!";
    4.     }
    6.     # the Perlish post-condition way
    7.     print "Yow!" if $zippy;
    8.     print "We have no bananas" unless $bananas;
  • while 
    1.     while ( condition ) {
    2.         ...
    3.     }

    There's also a negated version, for the same reason we have unless :

    1.     until ( condition ) {
    2.         ...
    3.     }

    You can also use while in a post-condition:

    1.     print "LA LA LA\n" while 1;          # loops forever
  • for

    Exactly like C:

    1.     for ($i=0; $i <= $max; $i++) {
    2.         ...
    3.     }

    The C style for loop is rarely needed in Perl since Perl provides the more friendly list scanning foreach loop.

  • foreach 
    1.     foreach (@array) {
    2.         print "This element is $_\n";
    3.     }
    5.     # you don't have to use the default $_ either...
    6.     foreach my $key (keys %hash) {
    7.         print "The value of $key is $hash{$key}\n";
    8.     }

For more detail on looping constructs (and some that weren't mentioned in this overview) see perlsyn.

Builtin operators and functions

Perl comes with a wide selection of builtin functions. Some of the ones we've already seen include print, sort and reverse. A list of them is given at the start of perlfunc and you can easily read about any given function by using perldoc -f <i>functionname</i>.

Perl operators are documented in full in perlop, but here are a few of the most common ones:

  • Arithmetic 
    1.     +   addition
    2.     -   subtraction
    3.     *   multiplication
    4.     /   division
  • Numeric comparison 
    1.     ==  equality
    2.     !=  inequality
    3.     <   less than
    4.     >   greater than
    5.     <=  less than or equal
    6.     >=  greater than or equal
  • String comparison 
    1.     eq  equality
    2.     ne  inequality
    3.     lt  less than
    4.     gt  greater than
    5.     le  less than or equal
    6.     ge  greater than or equal

    (Why do we have separate numeric and string comparisons? Because we don't have special variable types, and Perl needs to know whether to sort numerically (where 99 is less than 100) or alphabetically (where 100 comes before 99).

  • Boolean logic 
    1.     &&  and
    2.     ||  or
    3.     !   not

    (and , or and not aren't just in the above table as descriptions of the operators -- they're also supported as operators in their own right. They're more readable than the C-style operators, but have different precedence to && and friends. Check perlop for more detail.)

  • Miscellaneous 
    1.     =   assignment
    2.     .   string concatenation
    3.     x   string multiplication
    4.     ..  range operator (creates a list of numbers)

Many operators can be combined with a = as follows:

  1.     $a += 1;        # same as $a = $a + 1
  2.     $a -= 1;        # same as $a = $a - 1
  3.     $a .= "\n";     # same as $a = $a . "\n";

Files and I/O

You can open a file for input or output using the open() function. It's documented in extravagant detail in perlfunc and perlopentut, but in short:

  1.     open(INFILE,  "input.txt")   or die "Can't open input.txt: $!";
  2.     open(OUTFILE, ">output.txt") or die "Can't open output.txt: $!";
  3.     open(LOGFILE, ">>my.log")    or die "Can't open logfile: $!";

You can read from an open filehandle using the <> operator. In scalar context it reads a single line from the filehandle, and in list context it reads the whole file in, assigning each line to an element of the list:

  1.     my $line  = <INFILE>;
  2.     my @lines = <INFILE>;

Reading in the whole file at one time is called slurping. It can be useful but it may be a memory hog. Most text file processing can be done a line at a time with Perl's looping constructs.

The <> operator is most often seen in a while loop:

  1.     while (<INFILE>) {     # assigns each line in turn to $_ 
  2.         print "Just read in this line: $_";
  3.     }

We've already seen how to print to standard output using print(). However, print() can also take an optional first argument specifying which filehandle to print to:

  1.     print STDERR "This is your final warning.\n";
  2.     print OUTFILE $record;
  3.     print LOGFILE $logmessage;

When you're done with your filehandles, you should close() them (though to be honest, Perl will clean up after you if you forget):

  1.     close INFILE;

Regular expressions

Perl's regular expression support is both broad and deep, and is the subject of lengthy documentation in perlrequick, perlretut, and elsewhere. However, in short:

  • Simple matching 
    1.     if (/foo/)       { ... }  # true if $_ contains "foo"
    2.     if ($a =~ /foo/) { ... }  # true if $a contains "foo"

    The // matching operator is documented in perlop. It operates on $_ by default, or can be bound to another variable using the =~ binding operator (also documented in perlop).

  • Simple substitution 
    1.     s/foo/bar/;               # replaces foo with bar in $_
    2.     $a =~ s/foo/bar/;         # replaces foo with bar in $a
    3.     $a =~ s/foo/bar/g;        # replaces ALL INSTANCES of foo with bar in $a

    The s/// substitution operator is documented in perlop.

  • More complex regular expressions

    You don't just have to match on fixed strings. In fact, you can match on just about anything you could dream of by using more complex regular expressions. These are documented at great length in perlre, but for the meantime, here's a quick cheat sheet:

    1.     .                   a single character
    2.     \s                  a whitespace character (space, tab, newline)
    3.     \S                  non-whitespace character
    4.     \d                  a digit (0-9)
    5.     \D                  a non-digit
    6.     \w                  a word character (a-z, A-Z, 0-9, _)
    7.     \W                  a non-word character
    8.     [aeiou]             matches a single character in the given set
    9.     [^aeiou]            matches a single character outside the given set
    10.     (foo|bar|baz)       matches any of the alternatives specified
    12.     ^                   start of string
    13.     $                   end of string

    Quantifiers can be used to specify how many of the previous thing you want to match on, where "thing" means either a literal character, one of the metacharacters listed above, or a group of characters or metacharacters in parentheses.

    1.     *                   zero or more of the previous thing
    2.     +                   one or more of the previous thing
    3.     ?                   zero or one of the previous thing
    4.     {3}                 matches exactly 3 of the previous thing
    5.     {3,6}               matches between 3 and 6 of the previous thing
    6.     {3,}                matches 3 or more of the previous thing

    Some brief examples:

    1.     /^\d+/              string starts with one or more digits
    2.     /^$/                nothing in the string (start and end are adjacent)
    3.     /(\d\s){3}/         a three digits, each followed by a whitespace 
    4.                         character (eg "3 4 5 ")
    5.     /(a.)+/             matches a string in which every odd-numbered letter 
    6.                         is a (eg "abacadaf")
    8.     # This loop reads from STDIN, and prints non-blank lines:
    9.     while (<>) {
    10.         next if /^$/;
    11.         print;
    12.     }
  • Parentheses for capturing

    As well as grouping, parentheses serve a second purpose. They can be used to capture the results of parts of the regexp match for later use. The results end up in $1 , $2 and so on.

    1.     # a cheap and nasty way to break an email address up into parts
    3.     if ($email =~ /([^@]+)@(.+)/) {
    4.         print "Username is $1\n";
    5.         print "Hostname is $2\n";
    6.     }
  • Other regexp features

    Perl regexps also support backreferences, lookaheads, and all kinds of other complex details. Read all about them in perlrequick, perlretut, and perlre.

Writing subroutines

Writing subroutines is easy:

  1.     sub log {
  2.         my $logmessage = shift;
  3.         print LOGFILE $logmessage;
  4.     }

What's that shift? Well, the arguments to a subroutine are available to us as a special array called @_ (see perlvar for more on that). The default argument to the shift function just happens to be @_ . So my $logmessage = shift; shifts the first item off the list of arguments and assigns it to $logmessage .

We can manipulate @_ in other ways too:

  1.     my ($logmessage, $priority) = @_;       # common
  2.     my $logmessage = $_[0];                 # uncommon, and ugly

Subroutines can also return values:

  1.     sub square {
  2.         my $num = shift;
  3.         my $result = $num * $num;
  4.         return $result;
  5.     }

For more information on writing subroutines, see perlsub.

OO Perl

OO Perl is relatively simple and is implemented using references which know what sort of object they are based on Perl's concept of packages. However, OO Perl is largely beyond the scope of this document. Read perlboot, perltoot, perltooc and perlobj.

As a beginning Perl programmer, your most common use of OO Perl will be in using third-party modules, which are documented below.

Using Perl modules

Perl modules provide a range of features to help you avoid reinventing the wheel, and can be downloaded from CPAN ( http://www.cpan.org/ ). A number of popular modules are included with the Perl distribution itself.

Categories of modules range from text manipulation to network protocols to database integration to graphics. A categorized list of modules is also available from CPAN.

To learn how to install modules you download from CPAN, read perlmodinstall

To learn how to use a particular module, use perldoc <i>Module::Name</i>. Typically you will want to use <i>Module::Name</i>, which will then give you access to exported functions or an OO interface to the module.

perlfaq contains questions and answers related to many common tasks, and often provides suggestions for good CPAN modules to use.

perlmod describes Perl modules in general. perlmodlib lists the modules which came with your Perl installation.

If you feel the urge to write Perl modules, perlnewmod will give you good advice.

AUTHOR

Kirrily "Skud" Robert <skud@cpan.org>

Page index