Term::ANSIColor - Color screen output using ANSI escape sequences
- use Term::ANSIColor;
- print color 'bold blue';
- print "This text is bold blue.\n";
- print color 'reset';
- print "This text is normal.\n";
- print colored ("Yellow on magenta.", 'yellow on_magenta'), "\n";
- print "This text is normal.\n";
- print colored ['yellow on_magenta'], 'Yellow on magenta.', "\n";
- print colored ['red on_bright_yellow'] 'Red on bright yellow.', "\n";
- print colored ['bright_red on_black], 'Bright red on black.', "\n";
- print "\n";
- use Term::ANSIColor qw(uncolor);
- print uncolor ('01;31'), "\n";
- use Term::ANSIColor qw(colorstrip);
- print colorstrip '\e[1mThis is bold\e[0m', "\n";
- use Term::ANSIColor qw(colorvalid);
- my $valid = colorvalid ('blue bold', 'on_magenta');
- print "Color string is ", $valid ? "valid\n" : "invalid\n";
- use Term::ANSIColor qw(:constants);
- print BOLD, BLUE, "This text is in bold blue.\n", RESET;
- use Term::ANSIColor qw(:constants);
- {
- local $Term::ANSIColor::AUTORESET = 1;
- print BOLD BLUE "This text is in bold blue.\n";
- print "This text is normal.\n";
- }
- use Term::ANSIColor qw(:pushpop);
- print PUSHCOLOR RED ON_GREEN "This text is red on green.\n";
- print PUSHCOLOR BRIGHT_BLUE "This text is bright blue on green.\n";
- print RESET BRIGHT_BLUE "This text is just bright blue.\n";
- print POPCOLOR "Back to red on green.\n";
- print LOCALCOLOR GREEN ON_BLUE "This text is green on blue.\n";
- print "This text is red on green.\n";
- {
- local $Term::ANSIColor::AUTOLOCAL = 1;
- print ON_BLUE "This text is red on blue.\n";
- print "This text is red on green.\n";
- }
- print POPCOLOR "Back to whatever we started as.\n";
This module has two interfaces, one through color() and colored() and the other through constants. It also offers the utility functions uncolor(), colorstrip(), and colorvalid(), which have to be explicitly imported to be used (see SYNOPSIS).
Terminal emulators that support color divide into two types: ones that support only eight colors, and ones that support sixteen. This module provides both the ANSI escape codes for the "normal" colors, supported by both types, as well as the additional colors supported by sixteen-color emulators. These colors are referred to as ANSI colors 0 through 7 (normal) and 8 through 15.
Unfortunately, interpretation of colors 0 through 7 often depends on whether the emulator supports eight colors or sixteen colors. Emulators that only support eight colors (such as the Linux console) will display colors 0 through 7 with normal brightness and ignore colors 8 through 15, treating them the same as white. Emulators that support 16 colors, such as gnome-terminal, normally display colors 0 through 7 as dim or darker versions and colors 8 through 15 as normal brightness. On such emulators, the "normal" white (color 7) usually is shown as pale grey, requiring bright white (15) to be used to get a real white color. Bright black usually is a dark grey color, although some terminals display it as pure black. Some sixteen-color terminal emulators also treat normal yellow (color 3) as orange or brown, and bright yellow (color 11) as yellow.
Following the normal convention of sixteen-color emulators, this module
provides a pair of attributes for each color. For every normal color (0
through 7), the corresponding bright color (8 through 15) is obtained by
prepending the string bright_
to the normal color name. For example,
red
is color 1 and bright_red
is color 9. The same applies for
background colors: on_red
is the normal color and on_bright_red
is
the bright color. Capitalize these strings for the constant interface.
There is unfortunately no way to know whether the current emulator supports sixteen colors or not, which makes the choice of colors difficult. The most conservative choice is to use only the regular colors, which are at least displayed on all emulators. However, they will appear dark in sixteen-color terminal emulators, including most common emulators in UNIX X environments. If you know the display is one of those emulators, you may wish to use the bright variants instead. Even better, offer the user a way to configure the colors for a given application to fit their terminal emulator.
Support for colors 8 through 15 (the bright_
variants) was added in
Term::ANSIColor 3.0.
The function interface uses attribute strings to describe the colors and text attributes to assign to text. The recognized non-color attributes are clear, reset, bold, dark, faint, underline, underscore, blink, reverse, and concealed. Clear and reset (reset to default attributes), dark and faint (dim and saturated), and underline and underscore are equivalent, so use whichever is the most intuitive to you.
Note that not all attributes are supported by all terminal types, and some terminals may not support any of these sequences. Dark and faint, blink, and concealed in particular are frequently not implemented.
The recognized normal foreground color attributes (colors 0 to 7) are:
- black red green yellow blue magenta cyan white
The corresponding bright foreground color attributes (colors 8 to 15) are:
- bright_black bright_red bright_green bright_yellow
- bright_blue bright_magenta bright_cyan bright_white
The recognized normal background color attributes (colors 0 to 7) are:
- on_black on_red on_green on yellow
- on_blue on_magenta on_cyan on_white
The recognized bright background color attributes (colors 8 to 15) are:
- on_bright_black on_bright_red on_bright_green on_bright_yellow
- on_bright_blue on_bright_magenta on_bright_cyan on_bright_white
For any of the above listed attributes, case is not significant.
Attributes, once set, last until they are unset (by printing the attribute
clear
or reset). Be careful to do this, or otherwise your attribute
will last after your script is done running, and people get very annoyed
at having their prompt and typing changed to weird colors.
color() takes any number of strings as arguments and considers them to be space-separated lists of attributes. It then forms and returns the escape sequence to set those attributes. It doesn't print it out, just returns it, so you'll have to print it yourself if you want to. This is so that you can save it as a string, pass it to something else, send it to a file handle, or do anything else with it that you might care to. color() throws an exception if given an invalid attribute.
As an aid in resetting colors, colored() takes a scalar as the first argument and any number of attribute strings as the second argument and returns the scalar wrapped in escape codes so that the attributes will be set as requested before the string and reset to normal after the string. Alternately, you can pass a reference to an array as the first argument, and then the contents of that array will be taken as attributes and color codes and the remainder of the arguments as text to colorize.
Normally, colored() just puts attribute codes at the beginning and end of
the string, but if you set $Term::ANSIColor::EACHLINE to some string, that
string will be considered the line delimiter and the attribute will be set
at the beginning of each line of the passed string and reset at the end of
each line. This is often desirable if the output contains newlines and
you're using background colors, since a background color that persists
across a newline is often interpreted by the terminal as providing the
default background color for the next line. Programs like pagers can also
be confused by attributes that span lines. Normally you'll want to set
$Term::ANSIColor::EACHLINE to "\n"
to use this feature.
uncolor() performs the opposite translation as color(), turning escape sequences into a list of strings corresponding to the attributes being set by those sequences.
colorstrip() removes all color escape sequences from the provided strings, returning the modified strings separately in array context or joined together in scalar context. Its arguments are not modified.
colorvalid() takes attribute strings the same as color() and returns true if all attributes are known and false otherwise.
Alternately, if you import :constants
, you can use the following
constants directly:
- CLEAR RESET BOLD DARK
- FAINT UNDERLINE UNDERSCORE BLINK
- REVERSE CONCEALED
- BLACK RED GREEN YELLOW
- BLUE MAGENTA CYAN WHITE
- BRIGHT_BLACK BRIGHT_RED BRIGHT_GREEN BRIGHT_YELLOW
- BRIGHT_BLUE BRIGHT_MAGENTA BRIGHT_CYAN BRIGHT_WHITE
- ON_BLACK ON_RED ON_GREEN ON_YELLOW
- ON_BLUE ON_MAGENTA ON_CYAN ON_WHITE
- ON_BRIGHT_BLACK ON_BRIGHT_RED ON_BRIGHT_GREEN ON_BRIGHT_YELLOW
- ON_BRIGHT_BLUE ON_BRIGHT_MAGENTA ON_BRIGHT_CYAN ON_BRIGHT_WHITE
These are the same as color('attribute') and can be used if you prefer typing:
- print BOLD BLUE ON_WHITE "Text", RESET, "\n";
to
- print colored ("Text", 'bold blue on_white'), "\n";
(Note that the newline is kept separate to avoid confusing the terminal as described above since a background color is being used.)
When using the constants, if you don't want to have to remember to add the
, RESET
at the end of each print line, you can set
$Term::ANSIColor::AUTORESET to a true value. Then, the display mode will
automatically be reset if there is no comma after the constant. In other
words, with that variable set:
- print BOLD BLUE "Text\n";
will reset the display mode afterward, whereas:
- print BOLD, BLUE, "Text\n";
will not. If you are using background colors, you will probably want to print the newline with a separate print statement to avoid confusing the terminal.
The subroutine interface has the advantage over the constants interface in that only two subroutines are exported into your namespace, versus thirty-eight in the constants interface. On the flip side, the constants interface has the advantage of better compile time error checking, since misspelled names of colors or attributes in calls to color() and colored() won't be caught until runtime whereas misspelled names of constants will be caught at compile time. So, pollute your namespace with almost two dozen subroutines that you may not even use that often, or risk a silly bug by mistyping an attribute. Your choice, TMTOWTDI after all.
As of Term::ANSIColor 2.0, you can import :pushpop
and maintain a stack
of colors using PUSHCOLOR, POPCOLOR, and LOCALCOLOR. PUSHCOLOR takes the
attribute string that starts its argument and pushes it onto a stack of
attributes. POPCOLOR removes the top of the stack and restores the
previous attributes set by the argument of a prior PUSHCOLOR. LOCALCOLOR
surrounds its argument in a PUSHCOLOR and POPCOLOR so that the color
resets afterward.
When using PUSHCOLOR, POPCOLOR, and LOCALCOLOR, it's particularly important to not put commas between the constants.
- print PUSHCOLOR BLUE "Text\n";
will correctly push BLUE onto the top of the stack.
- print PUSHCOLOR, BLUE, "Text\n"; # wrong!
will not, and a subsequent pop won't restore the correct attributes. PUSHCOLOR pushes the attributes set by its argument, which is normally a string of color constants. It can't ask the terminal what the current attributes are.
(F) You passed an invalid ANSI escape sequence to uncolor().
(F) You probably mistyped a constant color name such as:
- $Foobar = FOOBAR . "This line should be blue\n";
or:
- @Foobar = FOOBAR, "This line should be blue\n";
This will only show up under use strict (another good reason to run under use strict).
(F) You passed an invalid attribute name to either color() or colored().
(W) You probably mistyped a constant color name such as:
- print FOOBAR "This text is color FOOBAR\n";
It's probably better to always use commas after constant names in order to force the next error.
(F) You probably mistyped a constant color name such as:
- print FOOBAR, "This text is color FOOBAR\n";
Generating this fatal compile error is one of the main advantages of using the constants interface, since you'll immediately know if you mistype a color name.
(F) The ANSI escape sequence passed to uncolor() contains escapes which aren't recognized and can't be translated to names.
If this environment variable is set, all of the functions defined by this module (color(), colored(), and all of the constants not previously used in the program) will not output any escape sequences and instead will just return the empty string or pass through the original text as appropriate. This is intended to support easy use of scripts using this module on platforms that don't support ANSI escape sequences.
For it to have its proper effect, this environment variable must be set before any color constants are used in the program.
It would be nice if one could leave off the commas around the constants entirely and just say:
- print BOLD BLUE ON_WHITE "Text\n" RESET;
but the syntax of Perl doesn't allow this. You need a comma after the string. (Of course, you may consider it a bug that commas between all the constants aren't required, in which case you may feel free to insert commas unless you're using $Term::ANSIColor::AUTORESET or PUSHCOLOR/POPCOLOR.)
For easier debugging, you may prefer to always use the commas when not setting $Term::ANSIColor::AUTORESET or PUSHCOLOR/POPCOLOR so that you'll get a fatal compile error rather than a warning.
The codes generated by this module are standard terminal control codes, complying with ECMA-048 and ISO 6429 (generally referred to as "ANSI color" for the color codes). The non-color control codes (bold, dark, italic, underline, and reverse) are part of the earlier ANSI X3.64 standard for control sequences for video terminals and peripherals.
Note that not all displays are ISO 6429-compliant, or even X3.64-compliant (or are even attempting to be so). This module will not work as expected on displays that do not honor these escape sequences, such as cmd.exe, 4nt.exe, and command.com under either Windows NT or Windows 2000. They may just be ignored, or they may display as an ESC character followed by some apparent garbage.
Jean Delvare provided the following table of different common terminal emulators and their support for the various attributes and others have helped me flesh it out:
- clear bold faint under blink reverse conceal
- ------------------------------------------------------------------------
- xterm yes yes no yes yes yes yes
- linux yes yes yes bold yes yes no
- rxvt yes yes no yes bold/black yes no
- dtterm yes yes yes yes reverse yes yes
- teraterm yes reverse no yes rev/red yes no
- aixterm kinda normal no yes no yes yes
- PuTTY yes color no yes no yes no
- Windows yes no no no no yes no
- Cygwin SSH yes yes no color color color yes
- Mac Terminal yes yes no yes yes yes yes
Windows is Windows telnet, Cygwin SSH is the OpenSSH implementation under Cygwin on Windows NT, and Mac Terminal is the Terminal application in Mac OS X. Where the entry is other than yes or no, that emulator displays the given attribute as something else instead. Note that on an aixterm, clear doesn't reset colors; you have to explicitly set the colors back to what you want. More entries in this table are welcome.
Note that codes 3 (italic), 6 (rapid blink), and 9 (strike-through) are specified in ANSI X3.64 and ECMA-048 but are not commonly supported by most displays and emulators and therefore aren't supported by this module at the present time. ECMA-048 also specifies a large number of other attributes, including a sequence of attributes for font changes, Fraktur characters, double-underlining, framing, circling, and overlining. As none of these attributes are widely supported or useful, they also aren't currently supported by this module.
ECMA-048 is available on-line (at least at the time of this writing) at http://www.ecma-international.org/publications/standards/ECMA-048.HTM.
ISO 6429 is available from ISO for a charge; the author of this module does not own a copy of it. Since the source material for ISO 6429 was ECMA-048 and the latter is available for free, there seems little reason to obtain the ISO standard.
The current version of this module is always available from its web site at http://www.eyrie.org/~eagle/software/ansicolor/. It is also part of the Perl core distribution as of 5.6.0.
Original idea (using constants) by Zenin, reimplemented using subs by Russ Allbery <rra@stanford.edu>, and then combined with the original idea by Russ with input from Zenin. Russ Allbery now maintains this module.
Copyright 1996, 1997, 1998, 2000, 2001, 2002, 2005, 2006, 2008, 2009, 2010 Russ Allbery <rra@stanford.edu> and Zenin. This program is free software; you may redistribute it and/or modify it under the same terms as Perl itself.
PUSHCOLOR, POPCOLOR, and LOCALCOLOR were contributed by openmethods.com voice solutions.