• TUX



Perl 5 version 18.1 documentation
Recently read


  • our EXPR

  • our TYPE EXPR
  • our EXPR : ATTRS

    our makes a lexical alias to a package variable of the same name in the current package for use within the current lexical scope.

    our has the same scoping rules as my or state, but our only declares an alias, whereas my or state both declare a variable name and allocate storage for that name within the current scope.

    This means that when use strict 'vars' is in effect, our lets you use a package variable without qualifying it with the package name, but only within the lexical scope of the our declaration. In this way, our differs from use vars , which allows use of an unqualified name only within the affected package, but across scopes.

    If more than one value is listed, the list must be placed in parentheses.

    1. our $foo;
    2. our($bar, $baz);

    An our declaration declares an alias for a package variable that will be visible across its entire lexical scope, even across package boundaries. The package in which the variable is entered is determined at the point of the declaration, not at the point of use. This means the following behavior holds:

    1. package Foo;
    2. our $bar; # declares $Foo::bar for rest of lexical scope
    3. $bar = 20;
    4. package Bar;
    5. print $bar; # prints 20, as it refers to $Foo::bar

    Multiple our declarations with the same name in the same lexical scope are allowed if they are in different packages. If they happen to be in the same package, Perl will emit warnings if you have asked for them, just like multiple my declarations. Unlike a second my declaration, which will bind the name to a fresh variable, a second our declaration in the same package, in the same scope, is merely redundant.

    1. use warnings;
    2. package Foo;
    3. our $bar; # declares $Foo::bar for rest of lexical scope
    4. $bar = 20;
    5. package Bar;
    6. our $bar = 30; # declares $Bar::bar for rest of lexical scope
    7. print $bar; # prints 30
    8. our $bar; # emits warning but has no other effect
    9. print $bar; # still prints 30

    An our declaration may also have a list of attributes associated with it.

    The exact semantics and interface of TYPE and ATTRS are still evolving. TYPE is currently bound to the use of the fields pragma, and attributes are handled using the attributes pragma, or, starting from Perl 5.8.0, also via the Attribute::Handlers module. See Private Variables via my() in perlsub for details, and fields, attributes, and Attribute::Handlers.