Manual

Reference

Modules

  • A • B • C • D • E
  • F • G • H • I • L
  • M • N • O • P • S
  • T • U • X

Tools

feature

Perl 5 version 22.0 documentation
Go to top • Download PDF
Show page index • Show recent pages
Recently read

feature

NAME

feature - Perl pragma to enable new features

SYNOPSIS

  1.     use feature qw(say switch);
  2.     given ($foo) {
  3.         when (1)          { say "\$foo == 1" }
  4.         when ([2,3])      { say "\$foo == 2 || \$foo == 3" }
  5.         when (/^a[bc]d$/) { say "\$foo eq 'abd' || \$foo eq 'acd'" }
  6.         when ($_ > 100)   { say "\$foo > 100" }
  7.         default           { say "None of the above" }
  8.     }
  10.     use feature ':5.10'; # loads all features available in perl 5.10
  12.     use v5.10;           # implicitly loads :5.10 feature bundle

DESCRIPTION

It is usually impossible to add new syntax to Perl without breaking some existing programs. This pragma provides a way to minimize that risk. New syntactic constructs, or new semantic meanings to older constructs, can be enabled by use feature 'foo' , and will be parsed only when the appropriate feature pragma is in scope. (Nevertheless, the CORE:: prefix provides access to all Perl keywords, regardless of this pragma.)

Lexical effect

Like other pragmas (use strict , for example), features have a lexical effect. use feature qw(foo) will only make the feature "foo" available from that point to the end of the enclosing block.

  1.     {
  2.         use feature 'say';
  3.         say "say is available here";
  4.     }
  5.     print "But not here.\n";

no feature

Features can also be turned off by using no feature "foo" . This too has lexical effect.

  1.     use feature 'say';
  2.     say "say is available here";
  3.     {
  4.         no feature 'say';
  5.         print "But not here.\n";
  6.     }
  7.     say "Yet it is here.";

no feature with no features specified will reset to the default group. To disable all features (an unusual request!) use no feature ':all' .

AVAILABLE FEATURES

The 'say' feature

use feature 'say' tells the compiler to enable the Perl 6 style say function.

See say for details.

This feature is available starting with Perl 5.10.

The 'state' feature

use feature 'state' tells the compiler to enable state variables.

See Persistent Private Variables in perlsub for details.

This feature is available starting with Perl 5.10.

The 'switch' feature

WARNING: Because the smartmatch operator is experimental, Perl will warn when you use this feature, unless you have explicitly disabled the warning:

  1.     no warnings "experimental::smartmatch";

use feature 'switch' tells the compiler to enable the Perl 6 given/when construct.

See Switch Statements in perlsyn for details.

This feature is available starting with Perl 5.10.

The 'unicode_strings' feature

use feature 'unicode_strings' tells the compiler to use Unicode rules in all string operations executed within its scope (unless they are also within the scope of either use locale or use bytes ). The same applies to all regular expressions compiled within the scope, even if executed outside it. It does not change the internal representation of strings, but only how they are interpreted.

no feature 'unicode_strings' tells the compiler to use the traditional Perl rules wherein the native character set rules is used unless it is clear to Perl that Unicode is desired. This can lead to some surprises when the behavior suddenly changes. (See The Unicode Bug in perlunicode for details.) For this reason, if you are potentially using Unicode in your program, the use feature 'unicode_strings' subpragma is strongly recommended.

This feature is available starting with Perl 5.12; was almost fully implemented in Perl 5.14; and extended in Perl 5.16 to cover quotemeta.

The 'unicode_eval' and 'evalbytes' features

Under the unicode_eval feature, Perl's eval function, when passed a string, will evaluate it as a string of characters, ignoring any use utf8 declarations. use utf8 exists to declare the encoding of the script, which only makes sense for a stream of bytes, not a string of characters. Source filters are forbidden, as they also really only make sense on strings of bytes. Any attempt to activate a source filter will result in an error.

The evalbytes feature enables the evalbytes keyword, which evaluates the argument passed to it as a string of bytes. It dies if the string contains any characters outside the 8-bit range. Source filters work within evalbytes: they apply to the contents of the string being evaluated.

Together, these two features are intended to replace the historical eval function, which has (at least) two bugs in it, that cannot easily be fixed without breaking existing programs:

  • eval behaves differently depending on the internal encoding of the string, sometimes treating its argument as a string of bytes, and sometimes as a string of characters.

  • Source filters activated within eval leak out into whichever file scope is currently being compiled. To give an example with the CPAN module Semi::Semicolons:

    1.     BEGIN { eval "use Semi::Semicolons;  # not filtered here " }
    2.     # filtered here!

    evalbytes fixes that to work the way one would expect:

    1.     use feature "evalbytes";
    2.     BEGIN { evalbytes "use Semi::Semicolons;  # filtered " }
    3.     # not filtered

These two features are available starting with Perl 5.16.

The 'current_sub' feature

This provides the __SUB__ token that returns a reference to the current subroutine or undef outside of a subroutine.

This feature is available starting with Perl 5.16.

The 'array_base' feature

This feature supports the legacy $[ variable. See $[ in perlvar and arybase. It is on by default but disabled under use v5.16 (see IMPLICIT LOADING, below).

This feature is available under this name starting with Perl 5.16. In previous versions, it was simply on all the time, and this pragma knew nothing about it.

The 'fc' feature

use feature 'fc' tells the compiler to enable the fc function, which implements Unicode casefolding.

See fc for details.

This feature is available from Perl 5.16 onwards.

The 'lexical_subs' feature

WARNING: This feature is still experimental and the implementation may change in future versions of Perl. For this reason, Perl will warn when you use the feature, unless you have explicitly disabled the warning:

  1.     no warnings "experimental::lexical_subs";

This enables declaration of subroutines via my sub foo , state sub foo and our sub foo syntax. See Lexical Subroutines in perlsub for details.

This feature is available from Perl 5.18 onwards.

The 'postderef' and 'postderef_qq' features

WARNING: This feature is still experimental and the implementation may change in future versions of Perl. For this reason, Perl will warn when you use the feature, unless you have explicitly disabled the warning:

  1.   no warnings "experimental::postderef";

The 'postderef' feature allows the use of postfix dereference syntax. For example, it will make the following two statements equivalent:

  1.   my @x = @{ $h->{a} };
  2.   my @x = $h->{a}->@*;

The 'postderef_qq' feature extends this, for array and scalar dereference, to working inside of double-quotish interpolations.

This feature is available from Perl 5.20 onwards.

The 'signatures' feature

WARNING: This feature is still experimental and the implementation may change in future versions of Perl. For this reason, Perl will warn when you use the feature, unless you have explicitly disabled the warning:

  1.     no warnings "experimental::signatures";

This enables unpacking of subroutine arguments into lexical variables by syntax such as

  1.     sub foo ($left, $right) {
  2. 	return $left + $right;
  3.     }

See Signatures in perlsub for details.

This feature is available from Perl 5.20 onwards.

The 'refaliasing' feature

WARNING: This feature is still experimental and the implementation may change in future versions of Perl. For this reason, Perl will warn when you use the feature, unless you have explicitly disabled the warning:

  1.     no warnings "experimental::refaliasing";

This enables aliasing via assignment to references:

  1.     \$a = \$b; # $a and $b now point to the same scalar
  2.     \@a = \@b; #                     to the same array
  3.     \%a = \%b;
  4.     \&a = \&b;
  5.     foreach \%hash (@array_of_hash_refs) {
  6.         ...
  7.     }

See Assigning to References in perlref for details.

This feature is available from Perl 5.22 onwards.

The 'bitwise' feature

WARNING: This feature is still experimental and the implementation may change in future versions of Perl. For this reason, Perl will warn when you use the feature, unless you have explicitly disabled the warning:

  1.     no warnings "experimental::bitwise";

This makes the four standard bitwise operators (& | ^ ~ ) treat their operands consistently as numbers, and introduces four new dotted operators (&. |. ^. ~. ) that treat their operands consistently as strings. The same applies to the assignment variants (&= |= ^= &.= |.= ^.= ).

See Bitwise String Operators in perlop for details.

This feature is available from Perl 5.22 onwards.

FEATURE BUNDLES

It's possible to load multiple features together, using a feature bundle. The name of a feature bundle is prefixed with a colon, to distinguish it from an actual feature.

  1.   use feature ":5.10";

The following feature bundles are available:

  1.   bundle    features included
  2.   --------- -----------------
  3.   :default  array_base
  5.   :5.10     say state switch array_base
  7.   :5.12     say state switch unicode_strings array_base
  9.   :5.14     say state switch unicode_strings array_base
  11.   :5.16     say state switch unicode_strings
  12.             unicode_eval evalbytes current_sub fc
  14.   :5.18     say state switch unicode_strings
  15.             unicode_eval evalbytes current_sub fc
  17.   :5.20     say state switch unicode_strings
  18.             unicode_eval evalbytes current_sub fc
  20.   :5.22     say state switch unicode_strings
  21.             unicode_eval evalbytes current_sub fc

The :default bundle represents the feature set that is enabled before any use feature or no feature declaration.

Specifying sub-versions such as the 0 in 5.14.0 in feature bundles has no effect. Feature bundles are guaranteed to be the same for all sub-versions.

  1.   use feature ":5.14.0";    # same as ":5.14"
  2.   use feature ":5.14.1";    # same as ":5.14"

IMPLICIT LOADING

Instead of loading feature bundles by name, it is easier to let Perl do implicit loading of a feature bundle for you.

There are two ways to load the feature pragma implicitly:

  • By using the -E switch on the Perl command-line instead of -e . That will enable the feature bundle for that version of Perl in the main compilation unit (that is, the one-liner that follows -E ).

  • By explicitly requiring a minimum Perl version number for your program, with the use VERSION construct. That is,

    1.     use v5.10.0;

    will do an implicit

    1.     no feature ':all';
    2.     use feature ':5.10';

    and so on. Note how the trailing sub-version is automatically stripped from the version.

    But to avoid portability warnings (see use), you may prefer:

    1.     use 5.010;

    with the same effect.

    If the required version is older than Perl 5.10, the ":default" feature bundle is automatically loaded instead.

Page index