Manual

Reference

Modules

  • A • B • C • D • E
  • F • G • H • I • L
  • M • N • O • P • S
  • T • U • X

Tools

threads::shared

Perl 5 version 26.0 documentation
Go to top • Download PDF
Show page index • Show recent pages
Recently read

threads::shared

NAME

threads::shared - Perl extension for sharing data structures between threads

VERSION

This document describes threads::shared version 1.56

SYNOPSIS

  1.   use threads;
  2.   use threads::shared;
  4.   my $var :shared;
  5.   my %hsh :shared;
  6.   my @ary :shared;
  8.   my ($scalar, @array, %hash);
  9.   share($scalar);
  10.   share(@array);
  11.   share(%hash);
  13.   $var = $scalar_value;
  14.   $var = $shared_ref_value;
  15.   $var = shared_clone($non_shared_ref_value);
  16.   $var = shared_clone({'foo' => [qw/foo bar baz/]});
  18.   $hsh{'foo'} = $scalar_value;
  19.   $hsh{'bar'} = $shared_ref_value;
  20.   $hsh{'baz'} = shared_clone($non_shared_ref_value);
  21.   $hsh{'quz'} = shared_clone([1..3]);
  23.   $ary[0] = $scalar_value;
  24.   $ary[1] = $shared_ref_value;
  25.   $ary[2] = shared_clone($non_shared_ref_value);
  26.   $ary[3] = shared_clone([ {}, [] ]);
  28.   { lock(%hash); ...  }
  30.   cond_wait($scalar);
  31.   cond_timedwait($scalar, time() + 30);
  32.   cond_broadcast(@array);
  33.   cond_signal(%hash);
  35.   my $lockvar :shared;
  36.   # condition var != lock var
  37.   cond_wait($var, $lockvar);
  38.   cond_timedwait($var, time()+30, $lockvar);

DESCRIPTION

By default, variables are private to each thread, and each newly created thread gets a private copy of each existing variable. This module allows you to share variables across different threads (and pseudo-forks on Win32). It is used together with the threads module.

This module supports the sharing of the following data types only: scalars and scalar refs, arrays and array refs, and hashes and hash refs.

EXPORT

The following functions are exported by this module: share , shared_clone , is_shared , cond_wait , cond_timedwait , cond_signal and cond_broadcast

Note that if this module is imported when threads has not yet been loaded, then these functions all become no-ops. This makes it possible to write modules that will work in both threaded and non-threaded environments.

FUNCTIONS

  • share VARIABLE

    share takes a variable and marks it as shared:

    1.   my ($scalar, @array, %hash);
    2.   share($scalar);
    3.   share(@array);
    4.   share(%hash);

    share will return the shared rvalue, but always as a reference.

    Variables can also be marked as shared at compile time by using the :shared attribute:

    1.   my ($var, %hash, @array) :shared;

    Shared variables can only store scalars, refs of shared variables, or refs of shared data (discussed in next section):

    1.   my ($var, %hash, @array) :shared;
    2.   my $bork;
    4.   # Storing scalars
    5.   $var = 1;
    6.   $hash{'foo'} = 'bar';
    7.   $array[0] = 1.5;
    9.   # Storing shared refs
    10.   $var = \%hash;
    11.   $hash{'ary'} = \@array;
    12.   $array[1] = \$var;
    14.   # The following are errors:
    15.   #   $var = \$bork;                    # ref of non-shared variable
    16.   #   $hash{'bork'} = [];               # non-shared array ref
    17.   #   push(@array, { 'x' => 1 });       # non-shared hash ref
  • shared_clone REF

    shared_clone takes a reference, and returns a shared version of its argument, performing a deep copy on any non-shared elements. Any shared elements in the argument are used as is (i.e., they are not cloned).

    1.   my $cpy = shared_clone({'foo' => [qw/foo bar baz/]});

    Object status (i.e., the class an object is blessed into) is also cloned.

    1.   my $obj = {'foo' => [qw/foo bar baz/]};
    2.   bless($obj, 'Foo');
    3.   my $cpy = shared_clone($obj);
    4.   print(ref($cpy), "\n");         # Outputs 'Foo'

    For cloning empty array or hash refs, the following may also be used:

    1.   $var = &share([]);   # Same as $var = shared_clone([]);
    2.   $var = &share({});   # Same as $var = shared_clone({});

    Not all Perl data types can be cloned (e.g., globs, code refs). By default, shared_clone will croak if it encounters such items. To change this behaviour to a warning, then set the following:

    1.   $threads::shared::clone_warn = 1;

    In this case, undef will be substituted for the item to be cloned. If set to zero:

    1.   $threads::shared::clone_warn = 0;

    then the undef substitution will be performed silently.

  • is_shared VARIABLE

    is_shared checks if the specified variable is shared or not. If shared, returns the variable's internal ID (similar to refaddr() (see Scalar::Util). Otherwise, returns undef.

    1.   if (is_shared($var)) {
    2.       print("\$var is shared\n");
    3.   } else {
    4.       print("\$var is not shared\n");
    5.   }

    When used on an element of an array or hash, is_shared checks if the specified element belongs to a shared array or hash. (It does not check the contents of that element.)

    1.   my %hash :shared;
    2.   if (is_shared(%hash)) {
    3.       print("\%hash is shared\n");
    4.   }
    6.   $hash{'elem'} = 1;
    7.   if (is_shared($hash{'elem'})) {
    8.       print("\$hash{'elem'} is in a shared hash\n");
    9.   }
  • lock VARIABLE

    lock places a advisory lock on a variable until the lock goes out of scope. If the variable is locked by another thread, the lock call will block until it's available. Multiple calls to lock by the same thread from within dynamically nested scopes are safe -- the variable will remain locked until the outermost lock on the variable goes out of scope.

    lock follows references exactly one level:

    1.   my %hash :shared;
    2.   my $ref = \%hash;
    3.   lock($ref);           # This is equivalent to lock(%hash)

    Note that you cannot explicitly unlock a variable; you can only wait for the lock to go out of scope. This is most easily accomplished by locking the variable inside a block.

    1.   my $var :shared;
    2.   {
    3.       lock($var);
    4.       # $var is locked from here to the end of the block
    5.       ...
    6.   }
    7.   # $var is now unlocked

    As locks are advisory, they do not prevent data access or modification by another thread that does not itself attempt to obtain a lock on the variable.

    You cannot lock the individual elements of a container variable:

    1.   my %hash :shared;
    2.   $hash{'foo'} = 'bar';
    3.   #lock($hash{'foo'});          # Error
    4.   lock(%hash);                  # Works

    If you need more fine-grained control over shared variable access, see Thread::Semaphore.

  • cond_wait VARIABLE
  • cond_wait CONDVAR, LOCKVAR

    The cond_wait function takes a locked variable as a parameter, unlocks the variable, and blocks until another thread does a cond_signal or cond_broadcast for that same locked variable. The variable that cond_wait blocked on is re-locked after the cond_wait is satisfied. If there are multiple threads cond_wait ing on the same variable, all but one will re-block waiting to reacquire the lock on the variable. (So if you're only using cond_wait for synchronization, give up the lock as soon as possible). The two actions of unlocking the variable and entering the blocked wait state are atomic, the two actions of exiting from the blocked wait state and re-locking the variable are not.

    In its second form, cond_wait takes a shared, unlocked variable followed by a shared, locked variable. The second variable is unlocked and thread execution suspended until another thread signals the first variable.

    It is important to note that the variable can be notified even if no thread cond_signal or cond_broadcast on the variable. It is therefore important to check the value of the variable and go back to waiting if the requirement is not fulfilled. For example, to pause until a shared counter drops to zero:

    1.   { lock($counter); cond_wait($counter) until $counter == 0; }
  • cond_timedwait VARIABLE, ABS_TIMEOUT
  • cond_timedwait CONDVAR, ABS_TIMEOUT, LOCKVAR

    In its two-argument form, cond_timedwait takes a locked variable and an absolute timeout in epoch seconds (see time for more) as parameters, unlocks the variable, and blocks until the timeout is reached or another thread signals the variable. A false value is returned if the timeout is reached, and a true value otherwise. In either case, the variable is re-locked upon return.

    Like cond_wait , this function may take a shared, locked variable as an additional parameter; in this case the first parameter is an unlocked condition variable protected by a distinct lock variable.

    Again like cond_wait , waking up and reacquiring the lock are not atomic, and you should always check your desired condition after this function returns. Since the timeout is an absolute value, however, it does not have to be recalculated with each pass:

    1.   lock($var);
    2.   my $abs = time() + 15;
    3.   until ($ok = desired_condition($var)) {
    4.       last if !cond_timedwait($var, $abs);
    5.   }
    6.   # we got it if $ok, otherwise we timed out!
  • cond_signal VARIABLE

    The cond_signal function takes a locked variable as a parameter and unblocks one thread that's cond_wait ing on that variable. If more than one thread is blocked in a cond_wait on that variable, only one (and which one is indeterminate) will be unblocked.

    If there are no threads blocked in a cond_wait on the variable, the signal is discarded. By always locking before signaling, you can (with care), avoid signaling before another thread has entered cond_wait().

    cond_signal will normally generate a warning if you attempt to use it on an unlocked variable. On the rare occasions where doing this may be sensible, you can suppress the warning with:

    1.   { no warnings 'threads'; cond_signal($foo); }
  • cond_broadcast VARIABLE

    The cond_broadcast function works similarly to cond_signal . cond_broadcast , though, will unblock all the threads that are blocked in a cond_wait on the locked variable, rather than only one.

OBJECTS

threads::shared exports a version of bless REF that works on shared objects such that blessings propagate across threads.

  1.   # Create a shared 'Foo' object
  2.   my $foo :shared = shared_clone({});
  3.   bless($foo, 'Foo');
  5.   # Create a shared 'Bar' object
  6.   my $bar :shared = shared_clone({});
  7.   bless($bar, 'Bar');
  9.   # Put 'bar' inside 'foo'
  10.   $foo->{'bar'} = $bar;
  12.   # Rebless the objects via a thread
  13.   threads->create(sub {
  14.       # Rebless the outer object
  15.       bless($foo, 'Yin');
  17.       # Cannot directly rebless the inner object
  18.       #bless($foo->{'bar'}, 'Yang');
  20.       # Retrieve and rebless the inner object
  21.       my $obj = $foo->{'bar'};
  22.       bless($obj, 'Yang');
  23.       $foo->{'bar'} = $obj;
  25.   })->join();
  27.   print(ref($foo),          "\n");    # Prints 'Yin'
  28.   print(ref($foo->{'bar'}), "\n");    # Prints 'Yang'
  29.   print(ref($bar),          "\n");    # Also prints 'Yang'

NOTES

threads::shared is designed to disable itself silently if threads are not available. This allows you to write modules and packages that can be used in both threaded and non-threaded applications.

If you want access to threads, you must use threads before you use threads::shared . threads will emit a warning if you use it after threads::shared.

WARNINGS

  • cond_broadcast() called on unlocked variable
  • cond_signal() called on unlocked variable

    See cond_signal VARIABLE, above.

BUGS AND LIMITATIONS

When share is used on arrays, hashes, array refs or hash refs, any data they contain will be lost.

  1.   my @arr = qw(foo bar baz);
  2.   share(@arr);
  3.   # @arr is now empty (i.e., == ());
  5.   # Create a 'foo' object
  6.   my $foo = { 'data' => 99 };
  7.   bless($foo, 'foo');
  9.   # Share the object
  10.   share($foo);        # Contents are now wiped out
  11.   print("ERROR: \$foo is empty\n")
  12.       if (! exists($foo->{'data'}));

Therefore, populate such variables after declaring them as shared. (Scalar and scalar refs are not affected by this problem.)

Blessing a shared item after it has been nested in another shared item does not propagate the blessing to the shared reference:

  1.   my $foo = &share({});
  2.   my $bar = &share({});
  3.   $bar->{foo} = $foo;
  4.   bless($foo, 'baz');   # $foo is now of class 'baz',
  5.                         # but $bar->{foo} is unblessed.

Therefore, you should bless objects before sharing them.

It is often not wise to share an object unless the class itself has been written to support sharing. For example, a shared object's destructor may get called multiple times, once for each thread's scope exit, or may not get called at all if it is embedded inside another shared object. Another issue is that the contents of hash-based objects will be lost due to the above mentioned limitation. See examples/class.pl (in the CPAN distribution of this module) for how to create a class that supports object sharing.

Destructors may not be called on objects if those objects still exist at global destruction time. If the destructors must be called, make sure there are no circular references and that nothing is referencing the objects before the program ends.

Does not support splice on arrays. Does not support explicitly changing array lengths via $#array -- use push and pop instead.

Taking references to the elements of shared arrays and hashes does not autovivify the elements, and neither does slicing a shared array/hash over non-existent indices/keys autovivify the elements.

share() allows you to share($hashref->{key}) and share($arrayref->[idx]) without giving any error message. But the $hashref->{key} or $arrayref->[idx] is not shared, causing the error "lock can only be used on shared values" to occur when you attempt to lock($hashref->{key}) or lock($arrayref->[idx]) in another thread.

Using refaddr() is unreliable for testing whether or not two shared references are equivalent (e.g., when testing for circular references). Use is_shared(), instead:

  1.     use threads;
  2.     use threads::shared;
  3.     use Scalar::Util qw(refaddr);
  5.     # If ref is shared, use threads::shared's internal ID.
  6.     # Otherwise, use refaddr().
  7.     my $addr1 = is_shared($ref1) || refaddr($ref1);
  8.     my $addr2 = is_shared($ref2) || refaddr($ref2);
  10.     if ($addr1 == $addr2) {
  11.         # The refs are equivalent
  12.     }

each HASH does not work properly on shared references embedded in shared structures. For example:

  1.     my %foo :shared;
  2.     $foo{'bar'} = shared_clone({'a'=>'x', 'b'=>'y', 'c'=>'z'});
  4.     while (my ($key, $val) = each(%{$foo{'bar'}})) {
  5.         ...
  6.     }

Either of the following will work instead:

  1.     my $ref = $foo{'bar'};
  2.     while (my ($key, $val) = each(%{$ref})) {
  3.         ...
  4.     }
  6.     foreach my $key (keys(%{$foo{'bar'}})) {
  7.         my $val = $foo{'bar'}{$key};
  8.         ...
  9.     }

This module supports dual-valued variables created using dualvar() from Scalar::Util. However, while $! acts like a dualvar, it is implemented as a tied SV. To propagate its value, use the follow construct, if needed:

  1.     my $errno :shared = dualvar($!,$!);

View existing bug reports at, and submit any new bugs, problems, patches, etc. to: http://rt.cpan.org/Public/Dist/Display.html?Name=threads-shared

SEE ALSO

threads::shared on MetaCPAN: https://metacpan.org/release/threads-shared

Code repository for CPAN distribution: https://github.com/Dual-Life/threads-shared

threads, perlthrtut

http://www.perl.com/pub/a/2002/06/11/threads.html and http://www.perl.com/pub/a/2002/09/04/threads.html

Perl threads mailing list: http://lists.perl.org/list/ithreads.html

Sample code in the examples directory of this distribution on CPAN.

AUTHOR

Artur Bergman <sky AT crucially DOT net>

Documentation borrowed from the old Thread.pm.

CPAN version produced by Jerry D. Hedden <jdhedden AT cpan DOT org>.

LICENSE

threads::shared is released under the same license as Perl.

Page index