Manual

Reference

Modules

  • A • B • C • D • E
  • F • G • H • I • L
  • M • N • O • P • S
  • T • U • X

Tools

perlsub

Perl 5 version 8.9 documentation
Go to top • Download PDF
Show page index • Show recent pages
Recently read

perlsub

NAME

perlsub - Perl subroutines

SYNOPSIS

To declare subroutines: 

  1.     sub NAME;			  # A "forward" declaration.
  2.     sub NAME(PROTO);		  #  ditto, but with prototypes
  3.     sub NAME : ATTRS;		  #  with attributes
  4.     sub NAME(PROTO) : ATTRS;	  #  with attributes and prototypes
  6.     sub NAME BLOCK		  # A declaration and a definition.
  7.     sub NAME(PROTO) BLOCK	  #  ditto, but with prototypes
  8.     sub NAME : ATTRS BLOCK	  #  with attributes
  9.     sub NAME(PROTO) : ATTRS BLOCK #  with prototypes and attributes

To define an anonymous subroutine at runtime: 

  1.     $subref = sub BLOCK;		 # no proto
  2.     $subref = sub (PROTO) BLOCK;	 # with proto
  3.     $subref = sub : ATTRS BLOCK;	 # with attributes
  4.     $subref = sub (PROTO) : ATTRS BLOCK; # with proto and attributes

To import subroutines: 

  1.     use MODULE qw(NAME1 NAME2 NAME3);

To call subroutines: 

  1.     NAME(LIST);	   # & is optional with parentheses.
  2.     NAME LIST;	   # Parentheses optional if predeclared/imported.
  3.     &NAME(LIST);   # Circumvent prototypes.
  4.     &NAME;	   # Makes current @_ visible to called subroutine.

DESCRIPTION

Like many languages, Perl provides for user-defined subroutines. These may be located anywhere in the main program, loaded in from other files via the do, require, or use keywords, or generated on the fly using eval or anonymous subroutines. You can even call a function indirectly using a variable containing its name or a CODE reference.

The Perl model for function call and return values is simple: all functions are passed as parameters one single flat list of scalars, and all functions likewise return to their caller one single flat list of scalars. Any arrays or hashes in these call and return lists will collapse, losing their identities--but you may always use pass-by-reference instead to avoid this. Both call and return lists may contain as many or as few scalar elements as you'd like. (Often a function without an explicit return statement is called a subroutine, but there's really no difference from Perl's perspective.)

Any arguments passed in show up in the array @_ . Therefore, if you called a function with two arguments, those would be stored in $_[0] and $_[1] . The array @_ is a local array, but its elements are aliases for the actual scalar parameters. In particular, if an element $_[0] is updated, the corresponding argument is updated (or an error occurs if it is not updatable). If an argument is an array or hash element which did not exist when the function was called, that element is created only when (and if) it is modified or a reference to it is taken. (Some earlier versions of Perl created the element whether or not the element was assigned to.) Assigning to the whole array @_ removes that aliasing, and does not update any arguments.

A return statement may be used to exit a subroutine, optionally specifying the returned value, which will be evaluated in the appropriate context (list, scalar, or void) depending on the context of the subroutine call. If you specify no return value, the subroutine returns an empty list in list context, the undefined value in scalar context, or nothing in void context. If you return one or more aggregates (arrays and hashes), these will be flattened together into one large indistinguishable list.

If no return is found and if the last statement is an expression, its value is returned. If the last statement is a loop control structure like a foreach or a while , the returned value is unspecified. The empty sub returns the empty list.

Perl does not have named formal parameters. In practice all you do is assign to a my() list of these. Variables that aren't declared to be private are global variables. For gory details on creating private variables, see Private Variables via my() and Temporary Values via local(). To create protected environments for a set of functions in a separate package (and probably a separate file), see Packages in perlmod.

Example:

  1.     sub max {
  2. 	my $max = shift(@_);
  3. 	foreach $foo (@_) {
  4. 	    $max = $foo if $max < $foo;
  5. 	}
  6. 	return $max;
  7.     }
  8.     $bestday = max($mon,$tue,$wed,$thu,$fri);

Example:

  1.     # get a line, combining continuation lines
  2.     #  that start with whitespace
  4.     sub get_line {
  5. 	$thisline = $lookahead;  # global variables!
  6. 	LINE: while (defined($lookahead = <STDIN>)) {
  7. 	    if ($lookahead =~ /^[ \t]/) {
  8. 		$thisline .= $lookahead;
  9. 	    }
  10. 	    else {
  11. 		last LINE;
  12. 	    }
  13. 	}
  14. 	return $thisline;
  15.     }
  17.     $lookahead = <STDIN>;	# get first line
  18.     while (defined($line = get_line())) {
  19. 	...
  20.     }

Assigning to a list of private variables to name your arguments:

  1.     sub maybeset {
  2. 	my($key, $value) = @_;
  3. 	$Foo{$key} = $value unless $Foo{$key};
  4.     }

Because the assignment copies the values, this also has the effect of turning call-by-reference into call-by-value. Otherwise a function is free to do in-place modifications of @_ and change its caller's values. 

  1.     upcase_in($v1, $v2);  # this changes $v1 and $v2
  2.     sub upcase_in {
  3. 	for (@_) { tr/a-z/A-Z/ }
  4.     }

You aren't allowed to modify constants in this way, of course. If an argument were actually literal and you tried to change it, you'd take a (presumably fatal) exception. For example, this won't work: 

  1.     upcase_in("frederick");

It would be much safer if the upcase_in() function were written to return a copy of its parameters instead of changing them in place:

  1.     ($v3, $v4) = upcase($v1, $v2);  # this doesn't change $v1 and $v2
  2.     sub upcase {
  3. 	return unless defined wantarray;  # void context, do nothing
  4. 	my @parms = @_;
  5. 	for (@parms) { tr/a-z/A-Z/ }
  6.   	return wantarray ? @parms : $parms[0];
  7.     }

Notice how this (unprototyped) function doesn't care whether it was passed real scalars or arrays. Perl sees all arguments as one big, long, flat parameter list in @_ . This is one area where Perl's simple argument-passing style shines. The upcase() function would work perfectly well without changing the upcase() definition even if we fed it things like this:

  1.     @newlist   = upcase(@list1, @list2);
  2.     @newlist   = upcase( split /:/, $var );

Do not, however, be tempted to do this:

  1.     (@a, @b)   = upcase(@list1, @list2);

Like the flattened incoming parameter list, the return list is also flattened on return. So all you have managed to do here is stored everything in @a and made @b empty. See Pass by Reference for alternatives.

A subroutine may be called using an explicit & prefix. The & is optional in modern Perl, as are parentheses if the subroutine has been predeclared. The & is not optional when just naming the subroutine, such as when it's used as an argument to defined() or undef(). Nor is it optional when you want to do an indirect subroutine call with a subroutine name or reference using the &$subref() or &{$subref}() constructs, although the $subref->() notation solves that problem. See perlref for more about all that.

Subroutines may be called recursively. If a subroutine is called using the & form, the argument list is optional, and if omitted, no @_ array is set up for the subroutine: the @_ array at the time of the call is visible to subroutine instead. This is an efficiency mechanism that new users may wish to avoid. 

  1.     &foo(1,2,3);	# pass three arguments
  2.     foo(1,2,3);		# the same
  4.     foo();		# pass a null list
  5.     &foo();		# the same
  7.     &foo;		# foo() get current args, like foo(@_) !!
  8.     foo;		# like foo() IFF sub foo predeclared, else "foo"

Not only does the & form make the argument list optional, it also disables any prototype checking on arguments you do provide. This is partly for historical reasons, and partly for having a convenient way to cheat if you know what you're doing. See Prototypes below.

Subroutines whose names are in all upper case are reserved to the Perl core, as are modules whose names are in all lower case. A subroutine in all capitals is a loosely-held convention meaning it will be called indirectly by the run-time system itself, usually due to a triggered event. Subroutines that do special, pre-defined things include AUTOLOAD , CLONE , DESTROY plus all functions mentioned in perltie and PerlIO::via.

The BEGIN , CHECK , INIT and END subroutines are not so much subroutines as named special code blocks, of which you can have more than one in a package, and which you can not call explicitly. See BEGIN, CHECK, INIT and END in perlmod

Private Variables via my()

Synopsis:

  1.     my $foo;	    	# declare $foo lexically local
  2.     my (@wid, %get); 	# declare list of variables local
  3.     my $foo = "flurp";	# declare $foo lexical, and init it
  4.     my @oof = @bar;	# declare @oof lexical, and init it
  5.     my $x : Foo = $y;	# similar, with an attribute applied

WARNING: The use of attribute lists on my declarations is still evolving. The current semantics and interface are subject to change. See attributes and Attribute::Handlers.

The my operator declares the listed variables to be lexically confined to the enclosing block, conditional (if/unless/elsif/else), loop (for/foreach/while/until/continue), subroutine, eval, or do/require/use'd file. If more than one value is listed, the list must be placed in parentheses. All listed elements must be legal lvalues. Only alphanumeric identifiers may be lexically scoped--magical built-ins like $/ must currently be localized with local instead.

Unlike dynamic variables created by the local operator, lexical variables declared with my are totally hidden from the outside world, including any called subroutines. This is true if it's the same subroutine called from itself or elsewhere--every call gets its own copy.

This doesn't mean that a my variable declared in a statically enclosing lexical scope would be invisible. Only dynamic scopes are cut off. For example, the bumpx() function below has access to the lexical $x variable because both the my and the sub occurred at the same scope, presumably file scope.

  1.     my $x = 10;
  2.     sub bumpx { $x++ }

An eval(), however, can see lexical variables of the scope it is being evaluated in, so long as the names aren't hidden by declarations within the eval() itself. See perlref.

The parameter list to my() may be assigned to if desired, which allows you to initialize your variables. (If no initializer is given for a particular variable, it is created with the undefined value.) Commonly this is used to name input parameters to a subroutine. Examples:

  1.     $arg = "fred";	  # "global" variable
  2.     $n = cube_root(27);
  3.     print "$arg thinks the root is $n\n";
  4.  fred thinks the root is 3
  6.     sub cube_root {
  7. 	my $arg = shift;  # name doesn't matter
  8. 	$arg **= 1/3;
  9. 	return $arg;
  10.     }

The my is simply a modifier on something you might assign to. So when you do assign to variables in its argument list, my doesn't change whether those variables are viewed as a scalar or an array. So

  1.     my ($foo) = <STDIN>;		# WRONG?
  2.     my @FOO = <STDIN>;

both supply a list context to the right-hand side, while

  1.     my $foo = <STDIN>;

supplies a scalar context. But the following declares only one variable:

  1.     my $foo, $bar = 1;			# WRONG

That has the same effect as

  1.     my $foo;
  2.     $bar = 1;

The declared variable is not introduced (is not visible) until after the current statement. Thus,

  1.     my $x = $x;

can be used to initialize a new $x with the value of the old $x, and the expression

  1.     my $x = 123 and $x == 123

is false unless the old $x happened to have the value 123 .

Lexical scopes of control structures are not bounded precisely by the braces that delimit their controlled blocks; control expressions are part of that scope, too. Thus in the loop

  1.     while (my $line = <>) {
  2.         $line = lc $line;
  3.     } continue {
  4.         print $line;
  5.     }

the scope of $line extends from its declaration throughout the rest of the loop construct (including the continue clause), but not beyond it. Similarly, in the conditional

  1.     if ((my $answer = <STDIN>) =~ /^yes$/i) {
  2.         user_agrees();
  3.     } elsif ($answer =~ /^no$/i) {
  4.         user_disagrees();
  5.     } else {
  6. 	chomp $answer;
  7.         die "'$answer' is neither 'yes' nor 'no'";
  8.     }

the scope of $answer extends from its declaration through the rest of that conditional, including any elsif and else clauses, but not beyond it. See Simple statements in perlsyn for information on the scope of variables in statements with modifiers.

The foreach loop defaults to scoping its index variable dynamically in the manner of local. However, if the index variable is prefixed with the keyword my, or if there is already a lexical by that name in scope, then a new lexical is created instead. Thus in the loop 

  1.     for my $i (1, 2, 3) {
  2.         some_function();
  3.     }

the scope of $i extends to the end of the loop, but not beyond it, rendering the value of $i inaccessible within some_function() .

Some users may wish to encourage the use of lexically scoped variables. As an aid to catching implicit uses to package variables, which are always global, if you say

  1.     use strict 'vars';

then any variable mentioned from there to the end of the enclosing block must either refer to a lexical variable, be predeclared via our or use vars , or else must be fully qualified with the package name. A compilation error results otherwise. An inner block may countermand this with no strict 'vars' .

A my has both a compile-time and a run-time effect. At compile time, the compiler takes notice of it. The principal usefulness of this is to quiet use strict 'vars' , but it is also essential for generation of closures as detailed in perlref. Actual initialization is delayed until run time, though, so it gets executed at the appropriate time, such as each time through a loop, for example.

Variables declared with my are not part of any package and are therefore never fully qualified with the package name. In particular, you're not allowed to try to make a package variable (or other global) lexical:

  1.     my $pack::var;	# ERROR!  Illegal syntax
  2.     my $_;		# also illegal (currently)

In fact, a dynamic variable (also known as package or global variables) are still accessible using the fully qualified :: notation even while a lexical of the same name is also visible:

  1.     package main;
  2.     local $x = 10;
  3.     my    $x = 20;
  4.     print "$x and $::x\n";

That will print out 20 and 10 .

You may declare my variables at the outermost scope of a file to hide any such identifiers from the world outside that file. This is similar in spirit to C's static variables when they are used at the file level. To do this with a subroutine requires the use of a closure (an anonymous function that accesses enclosing lexicals). If you want to create a private subroutine that cannot be called from outside that block, it can declare a lexical variable containing an anonymous sub reference:

  1.     my $secret_version = '1.001-beta';
  2.     my $secret_sub = sub { print $secret_version };
  3.     &$secret_sub();

As long as the reference is never returned by any function within the module, no outside module can see the subroutine, because its name is not in any package's symbol table. Remember that it's not REALLY called $some_pack::secret_version or anything; it's just $secret_version, unqualified and unqualifiable.

This does not work with object methods, however; all object methods have to be in the symbol table of some package to be found. See Function Templates in perlref for something of a work-around to this.

Persistent Private Variables

Just because a lexical variable is lexically (also called statically) scoped to its enclosing block, eval, or do FILE, this doesn't mean that within a function it works like a C static. It normally works more like a C auto, but with implicit garbage collection.

Unlike local variables in C or C++, Perl's lexical variables don't necessarily get recycled just because their scope has exited. If something more permanent is still aware of the lexical, it will stick around. So long as something else references a lexical, that lexical won't be freed--which is as it should be. You wouldn't want memory being free until you were done using it, or kept around once you were done. Automatic garbage collection takes care of this for you.

This means that you can pass back or save away references to lexical variables, whereas to return a pointer to a C auto is a grave error. It also gives us a way to simulate C's function statics. Here's a mechanism for giving a function private variables with both lexical scoping and a static lifetime. If you do want to create something like C's static variables, just enclose the whole function in an extra block, and put the static variable outside the function but in the block.

  1.     {
  2. 	my $secret_val = 0;
  3. 	sub gimme_another {
  4. 	    return ++$secret_val;
  5. 	}
  6.     }
  7.     # $secret_val now becomes unreachable by the outside
  8.     # world, but retains its value between calls to gimme_another

If this function is being sourced in from a separate file via require or use, then this is probably just fine. If it's all in the main program, you'll need to arrange for the my to be executed early, either by putting the whole block above your main program, or more likely, placing merely a BEGIN code block around it to make sure it gets executed before your program starts to run:

  1.     BEGIN {
  2. 	my $secret_val = 0;
  3. 	sub gimme_another {
  4. 	    return ++$secret_val;
  5. 	}
  6.     }

See BEGIN, CHECK, INIT and END in perlmod about the special triggered code blocks, BEGIN , CHECK , INIT and END .

If declared at the outermost scope (the file scope), then lexicals work somewhat like C's file statics. They are available to all functions in that same file declared below them, but are inaccessible from outside that file. This strategy is sometimes used in modules to create private variables that the whole module can see.

Temporary Values via local()

WARNING: In general, you should be using my instead of local, because it's faster and safer. Exceptions to this include the global punctuation variables, global filehandles and formats, and direct manipulation of the Perl symbol table itself. local is mostly used when the current value of a variable must be visible to called subroutines.

Synopsis:

  1.     # localization of values
  3.     local $foo;			# make $foo dynamically local
  4.     local (@wid, %get);		# make list of variables local
  5.     local $foo = "flurp";	# make $foo dynamic, and init it
  6.     local @oof = @bar;		# make @oof dynamic, and init it
  8.     local $hash{key} = "val";	# sets a local value for this hash entry
  9.     local ($cond ? $v1 : $v2);	# several types of lvalues support
  10. 				# localization
  12.     # localization of symbols
  14.     local *FH;			# localize $FH, @FH, %FH, &FH  ...
  15.     local *merlyn = *randal;	# now $merlyn is really $randal, plus
  16.                                 #     @merlyn is really @randal, etc
  17.     local *merlyn = 'randal';	# SAME THING: promote 'randal' to *randal
  18.     local *merlyn = \$randal;   # just alias $merlyn, not @merlyn etc

A local modifies its listed variables to be "local" to the enclosing block, eval, or do FILE --and to any subroutine called from within that block. A local just gives temporary values to global (meaning package) variables. It does not create a local variable. This is known as dynamic scoping. Lexical scoping is done with my, which works more like C's auto declarations.

Some types of lvalues can be localized as well : hash and array elements and slices, conditionals (provided that their result is always localizable), and symbolic references. As for simple variables, this creates new, dynamically scoped values.

If more than one variable or expression is given to local, they must be placed in parentheses. This operator works by saving the current values of those variables in its argument list on a hidden stack and restoring them upon exiting the block, subroutine, or eval. This means that called subroutines can also reference the local variable, but not the global one. The argument list may be assigned to if desired, which allows you to initialize your local variables. (If no initializer is given for a particular variable, it is created with an undefined value.)

Because local is a run-time operator, it gets executed each time through a loop. Consequently, it's more efficient to localize your variables outside the loop.

Grammatical note on local()

A local is simply a modifier on an lvalue expression. When you assign to a localized variable, the local doesn't change whether its list is viewed as a scalar or an array. So

  1.     local($foo) = <STDIN>;
  2.     local @FOO = <STDIN>;

both supply a list context to the right-hand side, while

  1.     local $foo = <STDIN>;

supplies a scalar context.

Localization of special variables

If you localize a special variable, you'll be giving a new value to it, but its magic won't go away. That means that all side-effects related to this magic still work with the localized value.

This feature allows code like this to work :

  1.     # Read the whole contents of FILE in $slurp
  2.     { local $/ = undef; $slurp = <FILE>; }

Note, however, that this restricts localization of some values ; for example, the following statement dies, as of perl 5.9.0, with an error Modification of a read-only value attempted, because the $1 variable is magical and read-only :

  1.     local $1 = 2;

Similarly, but in a way more difficult to spot, the following snippet will die in perl 5.9.0 :

  1.     sub f { local $_ = "foo"; print }
  2.     for ($1) {
  3. 	# now $_ is aliased to $1, thus is magic and readonly
  4. 	f();
  5.     }

See next section for an alternative to this situation.

WARNING: Localization of tied arrays and hashes does not currently work as described. This will be fixed in a future release of Perl; in the meantime, avoid code that relies on any particular behaviour of localising tied arrays or hashes (localising individual elements is still okay). See Localising Tied Arrays and Hashes Is Broken in perl58delta for more details.

Localization of globs

The construct

  1.     local *name;

creates a whole new symbol table entry for the glob name in the current package. That means that all variables in its glob slot ($name, @name, %name, &name, and the name filehandle) are dynamically reset.

This implies, among other things, that any magic eventually carried by those variables is locally lost. In other words, saying local */ will not have any effect on the internal value of the input record separator.

Notably, if you want to work with a brand new value of the default scalar $_, and avoid the potential problem listed above about $_ previously carrying a magic value, you should use local *_ instead of local $_ .

Localization of elements of composite types

It's also worth taking a moment to explain what happens when you localize a member of a composite type (i.e. an array or hash element). In this case, the element is localized by name. This means that when the scope of the local() ends, the saved value will be restored to the hash element whose key was named in the local(), or the array element whose index was named in the local(). If that element was deleted while the local() was in effect (e.g. by a delete() from a hash or a shift() of an array), it will spring back into existence, possibly extending an array and filling in the skipped elements with undef. For instance, if you say

  1.     %hash = ( 'This' => 'is', 'a' => 'test' );
  2.     @ary  = ( 0..5 );
  3.     {
  4.          local($ary[5]) = 6;
  5.          local($hash{'a'}) = 'drill';
  6.          while (my $e = pop(@ary)) {
  7.              print "$e . . .\n";
  8.              last unless $e > 3;
  9.          }
  10.          if (@ary) {
  11.              $hash{'only a'} = 'test';
  12.              delete $hash{'a'};
  13.          }
  14.     }
  15.     print join(' ', map { "$_ $hash{$_}" } sort keys %hash),".\n";
  16.     print "The array has ",scalar(@ary)," elements: ",
  17.           join(', ', map { defined $_ ? $_ : 'undef' } @ary),"\n";

Perl will print

  1.     6 . . .
  2.     4 . . .
  3.     3 . . .
  4.     This is a test only a test.
  5.     The array has 6 elements: 0, 1, 2, undef, undef, 5

The behavior of local() on non-existent members of composite types is subject to change in future.

Lvalue subroutines

WARNING: Lvalue subroutines are still experimental and the implementation may change in future versions of Perl.

It is possible to return a modifiable value from a subroutine. To do this, you have to declare the subroutine to return an lvalue.

  1.     my $val;
  2.     sub canmod : lvalue {
  3. 	# return $val; this doesn't work, don't say "return"
  4. 	$val;
  5.     }
  6.     sub nomod {
  7. 	$val;
  8.     }
  10.     canmod() = 5;   # assigns to $val
  11.     nomod()  = 5;   # ERROR

The scalar/list context for the subroutine and for the right-hand side of assignment is determined as if the subroutine call is replaced by a scalar. For example, consider:

  1.     data(2,3) = get_data(3,4);

Both subroutines here are called in a scalar context, while in:

  1.     (data(2,3)) = get_data(3,4);

and in:

  1.     (data(2),data(3)) = get_data(3,4);

all the subroutines are called in a list context.

  • Lvalue subroutines are EXPERIMENTAL

    They appear to be convenient, but there are several reasons to be circumspect.

    You can't use the return keyword, you must pass out the value before falling out of subroutine scope. (see comment in example above). This is usually not a problem, but it disallows an explicit return out of a deeply nested loop, which is sometimes a nice way out.

    They violate encapsulation. A normal mutator can check the supplied argument before setting the attribute it is protecting, an lvalue subroutine never gets that chance. Consider;

    1.     my $some_array_ref = [];	# protected by mutators ??
    3.     sub set_arr { 		# normal mutator
    4. 	my $val = shift;
    5. 	die("expected array, you supplied ", ref $val)
    6. 	   unless ref $val eq 'ARRAY';
    7. 	$some_array_ref = $val;
    8.     }
    9.     sub set_arr_lv : lvalue {	# lvalue mutator
    10. 	$some_array_ref;
    11.     }
    13.     # set_arr_lv cannot stop this !
    14.     set_arr_lv() = { a => 1 };

Passing Symbol Table Entries (typeglobs)

WARNING: The mechanism described in this section was originally the only way to simulate pass-by-reference in older versions of Perl. While it still works fine in modern versions, the new reference mechanism is generally easier to work with. See below.

Sometimes you don't want to pass the value of an array to a subroutine but rather the name of it, so that the subroutine can modify the global copy of it rather than working with a local copy. In perl you can refer to all objects of a particular name by prefixing the name with a star: *foo . This is often known as a "typeglob", because the star on the front can be thought of as a wildcard match for all the funny prefix characters on variables and subroutines and such.

When evaluated, the typeglob produces a scalar value that represents all the objects of that name, including any filehandle, format, or subroutine. When assigned to, it causes the name mentioned to refer to whatever * value was assigned to it. Example:

  1.     sub doubleary {
  2. 	local(*someary) = @_;
  3. 	foreach $elem (@someary) {
  4. 	    $elem *= 2;
  5. 	}
  6.     }
  7.     doubleary(*foo);
  8.     doubleary(*bar);

Scalars are already passed by reference, so you can modify scalar arguments without using this mechanism by referring explicitly to $_[0] etc. You can modify all the elements of an array by passing all the elements as scalars, but you have to use the * mechanism (or the equivalent reference mechanism) to push, pop, or change the size of an array. It will certainly be faster to pass the typeglob (or reference).

Even if you don't want to modify an array, this mechanism is useful for passing multiple arrays in a single LIST, because normally the LIST mechanism will merge all the array values so that you can't extract out the individual arrays. For more on typeglobs, see Typeglobs and Filehandles in perldata.

When to Still Use local()

Despite the existence of my, there are still three places where the local operator still shines. In fact, in these three places, you must use local instead of my.

1.

You need to give a global variable a temporary value, especially $_.

The global variables, like @ARGV or the punctuation variables, must be localized with local(). This block reads in /etc/motd, and splits it up into chunks separated by lines of equal signs, which are placed in @Fields .

  1.     {
  2. 	local @ARGV = ("/etc/motd");
  3.         local $/ = undef;
  4.         local $_ = <>;	
  5. 	@Fields = split /^\s*=+\s*$/;
  6.     }

It particular, it's important to localize $_ in any routine that assigns to it. Look out for implicit assignments in while conditionals.

2.

You need to create a local file or directory handle or a local function.

A function that needs a filehandle of its own must use local() on a complete typeglob. This can be used to create new symbol table entries:

  1.     sub ioqueue {
  2.         local  (*READER, *WRITER);    # not my!
  3.         pipe    (READER,  WRITER)     or die "pipe: $!";
  4.         return (*READER, *WRITER);
  5.     }
  6.     ($head, $tail) = ioqueue();

See the Symbol module for a way to create anonymous symbol table entries.

Because assignment of a reference to a typeglob creates an alias, this can be used to create what is effectively a local function, or at least, a local alias.

  1.     {
  2.         local *grow = \&shrink; # only until this block exists
  3.         grow();                 # really calls shrink()
  4. 	move();			# if move() grow()s, it shrink()s too
  5.     }
  6.     grow();			# get the real grow() again

See Function Templates in perlref for more about manipulating functions by name in this way.

3.

You want to temporarily change just one element of an array or hash.

You can localize just one element of an aggregate. Usually this is done on dynamics:

  1.     {
  2. 	local $SIG{INT} = 'IGNORE';
  3. 	funct();			    # uninterruptible
  4.     } 
  5.     # interruptibility automatically restored here

But it also works on lexically declared aggregates. Prior to 5.005, this operation could on occasion misbehave.

Pass by Reference

If you want to pass more than one array or hash into a function--or return them from it--and have them maintain their integrity, then you're going to have to use an explicit pass-by-reference. Before you do that, you need to understand references as detailed in perlref. This section may not make much sense to you otherwise.

Here are a few simple examples. First, let's pass in several arrays to a function and have it pop all of then, returning a new list of all their former last elements:

  1.     @tailings = popmany ( \@a, \@b, \@c, \@d );
  3.     sub popmany {
  4. 	my $aref;
  5. 	my @retlist = ();
  6. 	foreach $aref ( @_ ) {
  7. 	    push @retlist, pop @$aref;
  8. 	}
  9. 	return @retlist;
  10.     }

Here's how you might write a function that returns a list of keys occurring in all the hashes passed to it:

  1.     @common = inter( \%foo, \%bar, \%joe );
  2.     sub inter {
  3. 	my ($k, $href, %seen); # locals
  4. 	foreach $href (@_) {
  5. 	    while ( $k = each %$href ) {
  6. 		$seen{$k}++;
  7. 	    }
  8. 	}
  9. 	return grep { $seen{$_} == @_ } keys %seen;
  10.     }

So far, we're using just the normal list return mechanism. What happens if you want to pass or return a hash? Well, if you're using only one of them, or you don't mind them concatenating, then the normal calling convention is ok, although a little expensive.

Where people get into trouble is here:

  1.     (@a, @b) = func(@c, @d);
  2. or
  3.     (%a, %b) = func(%c, %d);

That syntax simply won't work. It sets just @a or %a and clears the @b or %b . Plus the function didn't get passed into two separate arrays or hashes: it got one long list in @_ , as always.

If you can arrange for everyone to deal with this through references, it's cleaner code, although not so nice to look at. Here's a function that takes two array references as arguments, returning the two array elements in order of how many elements they have in them:

  1.     ($aref, $bref) = func(\@c, \@d);
  2.     print "@$aref has more than @$bref\n";
  3.     sub func {
  4. 	my ($cref, $dref) = @_;
  5. 	if (@$cref > @$dref) {
  6. 	    return ($cref, $dref);
  7. 	} else {
  8. 	    return ($dref, $cref);
  9. 	}
  10.     }

It turns out that you can actually do this also:

  1.     (*a, *b) = func(\@c, \@d);
  2.     print "@a has more than @b\n";
  3.     sub func {
  4. 	local (*c, *d) = @_;
  5. 	if (@c > @d) {
  6. 	    return (\@c, \@d);
  7. 	} else {
  8. 	    return (\@d, \@c);
  9. 	}
  10.     }

Here we're using the typeglobs to do symbol table aliasing. It's a tad subtle, though, and also won't work if you're using my variables, because only globals (even in disguise as locals) are in the symbol table.

If you're passing around filehandles, you could usually just use the bare typeglob, like *STDOUT , but typeglobs references work, too. For example:

  1.     splutter(\*STDOUT);
  2.     sub splutter {
  3. 	my $fh = shift;
  4. 	print $fh "her um well a hmmm\n";
  5.     }
  7.     $rec = get_rec(\*STDIN);
  8.     sub get_rec {
  9. 	my $fh = shift;
  10. 	return scalar <$fh>;
  11.     }

If you're planning on generating new filehandles, you could do this. Notice to pass back just the bare *FH, not its reference.

  1.     sub openit {
  2. 	my $path = shift;
  3. 	local *FH;
  4. 	return open (FH, $path) ? *FH : undef;
  5.     }

Prototypes

Perl supports a very limited kind of compile-time argument checking using function prototyping. If you declare

  1.     sub mypush (\@@)

then mypush() takes arguments exactly like push() does. The function declaration must be visible at compile time. The prototype affects only interpretation of new-style calls to the function, where new-style is defined as not using the & character. In other words, if you call it like a built-in function, then it behaves like a built-in function. If you call it like an old-fashioned subroutine, then it behaves like an old-fashioned subroutine. It naturally falls out from this rule that prototypes have no influence on subroutine references like \&foo or on indirect subroutine calls like &{$subref} or $subref->() .

Method calls are not influenced by prototypes either, because the function to be called is indeterminate at compile time, since the exact code called depends on inheritance.

Because the intent of this feature is primarily to let you define subroutines that work like built-in functions, here are prototypes for some other functions that parse almost exactly like the corresponding built-in.

  1.     Declared as			Called as
  3.     sub mylink ($$)	     mylink $old, $new
  4.     sub myvec ($$$)	     myvec $var, $offset, 1
  5.     sub myindex ($$;$)	     myindex &getstring, "substr"
  6.     sub mysyswrite ($$$;$)   mysyswrite $buf, 0, length($buf) - $off, $off
  7.     sub myreverse (@)	     myreverse $a, $b, $c
  8.     sub myjoin ($@)	     myjoin ":", $a, $b, $c
  9.     sub mypop (\@)	     mypop @array
  10.     sub mysplice (\@$$@)     mysplice @array, 0, 2, @pushme
  11.     sub mykeys (\%)	     mykeys %{$hashref}
  12.     sub myopen (*;$)	     myopen HANDLE, $name
  13.     sub mypipe (**)	     mypipe READHANDLE, WRITEHANDLE
  14.     sub mygrep (&@)	     mygrep { /foo/ } $a, $b, $c
  15.     sub myrand (;$)	     myrand 42
  16.     sub mytime ()	     mytime

Any backslashed prototype character represents an actual argument that absolutely must start with that character. The value passed as part of @_ will be a reference to the actual argument given in the subroutine call, obtained by applying \ to that argument.

You can also backslash several argument types simultaneously by using the \[] notation:

  1.     sub myref (\[$@%&*])

will allow calling myref() as

  1.     myref $var
  2.     myref @array
  3.     myref %hash
  4.     myref &sub
  5.     myref *glob

and the first argument of myref() will be a reference to a scalar, an array, a hash, a code, or a glob.

Unbackslashed prototype characters have special meanings. Any unbackslashed @ or % eats all remaining arguments, and forces list context. An argument represented by $ forces scalar context. An & requires an anonymous subroutine, which, if passed as the first argument, does not require the sub keyword or a subsequent comma.

A * allows the subroutine to accept a bareword, constant, scalar expression, typeglob, or a reference to a typeglob in that slot. The value will be available to the subroutine either as a simple scalar, or (in the latter two cases) as a reference to the typeglob. If you wish to always convert such arguments to a typeglob reference, use Symbol::qualify_to_ref() as follows:

  1.     use Symbol 'qualify_to_ref';
  3.     sub foo (*) {
  4. 	my $fh = qualify_to_ref(shift, caller);
  5. 	...
  6.     }

A semicolon separates mandatory arguments from optional arguments. It is redundant before @ or % , which gobble up everything else.

Note how the last three examples in the table above are treated specially by the parser. mygrep() is parsed as a true list operator, myrand() is parsed as a true unary operator with unary precedence the same as rand(), and mytime() is truly without arguments, just like time(). That is, if you say

  1.     mytime +2;

you'll get mytime() + 2 , not mytime(2) , which is how it would be parsed without a prototype.

The interesting thing about & is that you can generate new syntax with it, provided it's in the initial position: 

  1.     sub try (&@) {
  2. 	my($try,$catch) = @_;
  3. 	eval { &$try };
  4. 	if ($@) {
  5. 	    local $_ = $@;
  6. 	    &$catch;
  7. 	}
  8.     }
  9.     sub catch (&) { $_[0] }
  11.     try {
  12. 	die "phooey";
  13.     } catch {
  14. 	/phooey/ and print "unphooey\n";
  15.     };

That prints "unphooey" . (Yes, there are still unresolved issues having to do with visibility of @_ . I'm ignoring that question for the moment. (But note that if we make @_ lexically scoped, those anonymous subroutines can act like closures... (Gee, is this sounding a little Lispish? (Never mind.))))

And here's a reimplementation of the Perl grep operator: 

  1.     sub mygrep (&@) {
  2. 	my $code = shift;
  3. 	my @result;
  4. 	foreach $_ (@_) {
  5. 	    push(@result, $_) if &$code;
  6. 	}
  7. 	@result;
  8.     }

Some folks would prefer full alphanumeric prototypes. Alphanumerics have been intentionally left out of prototypes for the express purpose of someday in the future adding named, formal parameters. The current mechanism's main goal is to let module writers provide better diagnostics for module users. Larry feels the notation quite understandable to Perl programmers, and that it will not intrude greatly upon the meat of the module, nor make it harder to read. The line noise is visually encapsulated into a small pill that's easy to swallow.

If you try to use an alphanumeric sequence in a prototype you will generate an optional warning - "Illegal character in prototype...". Unfortunately earlier versions of Perl allowed the prototype to be used as long as its prefix was a valid prototype. The warning may be upgraded to a fatal error in a future version of Perl once the majority of offending code is fixed.

It's probably best to prototype new functions, not retrofit prototyping into older ones. That's because you must be especially careful about silent impositions of differing list versus scalar contexts. For example, if you decide that a function should take just one parameter, like this:

  1.     sub func ($) {
  2. 	my $n = shift;
  3. 	print "you gave me $n\n";
  4.     }

and someone has been calling it with an array or expression returning a list:

  1.     func(@foo);
  2.     func( split /:/ );

Then you've just supplied an automatic scalar in front of their argument, which can be more than a bit surprising. The old @foo which used to hold one thing doesn't get passed in. Instead, func() now gets passed in a 1 ; that is, the number of elements in @foo . And the split gets called in scalar context so it starts scribbling on your @_ parameter list. Ouch!

This is all very powerful, of course, and should be used only in moderation to make the world a better place.

Constant Functions

Functions with a prototype of () are potential candidates for inlining. If the result after optimization and constant folding is either a constant or a lexically-scoped scalar which has no other references, then it will be used in place of function calls made without & . Calls made using & are never inlined. (See constant.pm for an easy way to declare most constants.)

The following functions would all be inlined:

  1.     sub pi ()		{ 3.14159 }		# Not exact, but close.
  2.     sub PI ()		{ 4 * atan2 1, 1 }	# As good as it gets,
  3. 						# and it's inlined, too!
  4.     sub ST_DEV ()	{ 0 }
  5.     sub ST_INO ()	{ 1 }
  7.     sub FLAG_FOO ()	{ 1 << 8 }
  8.     sub FLAG_BAR ()	{ 1 << 9 }
  9.     sub FLAG_MASK ()	{ FLAG_FOO | FLAG_BAR }
  11.     sub OPT_BAZ ()	{ not (0x1B58 & FLAG_MASK) }
  13.     sub N () { int(OPT_BAZ) / 3 }
  15.     sub FOO_SET () { 1 if FLAG_MASK & FLAG_FOO }

Be aware that these will not be inlined; as they contain inner scopes, the constant folding doesn't reduce them to a single constant:

  1.     sub foo_set () { if (FLAG_MASK & FLAG_FOO) { 1 } }
  3.     sub baz_val () {
  4. 	if (OPT_BAZ) {
  5. 	    return 23;
  6. 	}
  7. 	else {
  8. 	    return 42;
  9. 	}
  10.     }

If you redefine a subroutine that was eligible for inlining, you'll get a mandatory warning. (You can use this warning to tell whether or not a particular subroutine is considered constant.) The warning is considered severe enough not to be optional because previously compiled invocations of the function will still be using the old value of the function. If you need to be able to redefine the subroutine, you need to ensure that it isn't inlined, either by dropping the () prototype (which changes calling semantics, so beware) or by thwarting the inlining mechanism in some other way, such as

  1.     sub not_inlined () {
  2.     	23 if $];
  3.     }

Overriding Built-in Functions

Many built-in functions may be overridden, though this should be tried only occasionally and for good reason. Typically this might be done by a package attempting to emulate missing built-in functionality on a non-Unix system.

Overriding may be done only by importing the name from a module at compile time--ordinary predeclaration isn't good enough. However, the use subs pragma lets you, in effect, predeclare subs via the import syntax, and these names may then override built-in ones:

  1.     use subs 'chdir', 'chroot', 'chmod', 'chown';
  2.     chdir $somewhere;
  3.     sub chdir { ... }

To unambiguously refer to the built-in form, precede the built-in name with the special package qualifier CORE:: . For example, saying CORE::open() always refers to the built-in open(), even if the current package has imported some other subroutine called &open() from elsewhere. Even though it looks like a regular function call, it isn't: you can't take a reference to it, such as the incorrect \&CORE::open might appear to produce.

Library modules should not in general export built-in names like open or chdir as part of their default @EXPORT list, because these may sneak into someone else's namespace and change the semantics unexpectedly. Instead, if the module adds that name to @EXPORT_OK , then it's possible for a user to import the name explicitly, but not implicitly. That is, they could say

  1.     use Module 'open';

and it would import the open override. But if they said

  1.     use Module;

they would get the default imports without overrides.

The foregoing mechanism for overriding built-in is restricted, quite deliberately, to the package that requests the import. There is a second method that is sometimes applicable when you wish to override a built-in everywhere, without regard to namespace boundaries. This is achieved by importing a sub into the special namespace CORE::GLOBAL:: . Here is an example that quite brazenly replaces the glob operator with something that understands regular expressions.

  1.     package REGlob;
  2.     require Exporter;
  3.     @ISA = 'Exporter';
  4.     @EXPORT_OK = 'glob';
  6.     sub import {
  7. 	my $pkg = shift;
  8. 	return unless @_;
  9. 	my $sym = shift;
  10. 	my $where = ($sym =~ s/^GLOBAL_// ? 'CORE::GLOBAL' : caller(0));
  11. 	$pkg->export($where, $sym, @_);
  12.     }
  14.     sub glob {
  15. 	my $pat = shift;
  16. 	my @got;
  17. 	if (opendir my $d, '.') { 
  18. 	    @got = grep /$pat/, readdir $d; 
  19. 	    closedir $d;   
  20. 	}
  21. 	return @got;
  22.     }
  23.     1;

And here's how it could be (ab)used:

  1.     #use REGlob 'GLOBAL_glob';	    # override glob() in ALL namespaces
  2.     package Foo;
  3.     use REGlob 'glob';		    # override glob() in Foo:: only
  4.     print for <^[a-z_]+\.pm\$>;	    # show all pragmatic modules

The initial comment shows a contrived, even dangerous example. By overriding glob globally, you would be forcing the new (and subversive) behavior for the glob operator for every namespace, without the complete cognizance or cooperation of the modules that own those namespaces. Naturally, this should be done with extreme caution--if it must be done at all.

The REGlob example above does not implement all the support needed to cleanly override perl's glob operator. The built-in glob has different behaviors depending on whether it appears in a scalar or list context, but our REGlob doesn't. Indeed, many perl built-in have such context sensitive behaviors, and these must be adequately supported by a properly written override. For a fully functional example of overriding glob, study the implementation of File::DosGlob in the standard library.

When you override a built-in, your replacement should be consistent (if possible) with the built-in native syntax. You can achieve this by using a suitable prototype. To get the prototype of an overridable built-in, use the prototype function with an argument of "CORE::builtin_name" (see prototype).

Note however that some built-ins can't have their syntax expressed by a prototype (such as system or chomp). If you override them you won't be able to fully mimic their original syntax.

The built-ins do, require and glob can also be overridden, but due to special magic, their original syntax is preserved, and you don't have to define a prototype for their replacements. (You can't override the do BLOCK syntax, though).

require has special additional dark magic: if you invoke your require replacement as require Foo::Bar , it will actually receive the argument "Foo/Bar.pm" in @_. See require.

And, as you'll have noticed from the previous example, if you override glob, the <*> glob operator is overridden as well.

In a similar fashion, overriding the readline function also overrides the equivalent I/O operator <FILEHANDLE> .

Finally, some built-ins (e.g. exists or grep) can't be overridden.

Autoloading

If you call a subroutine that is undefined, you would ordinarily get an immediate, fatal error complaining that the subroutine doesn't exist. (Likewise for subroutines being used as methods, when the method doesn't exist in any base class of the class's package.) However, if an AUTOLOAD subroutine is defined in the package or packages used to locate the original subroutine, then that AUTOLOAD subroutine is called with the arguments that would have been passed to the original subroutine. The fully qualified name of the original subroutine magically appears in the global $AUTOLOAD variable of the same package as the AUTOLOAD routine. The name is not passed as an ordinary argument because, er, well, just because, that's why...

Many AUTOLOAD routines load in a definition for the requested subroutine using eval(), then execute that subroutine using a special form of goto() that erases the stack frame of the AUTOLOAD routine without a trace. (See the source to the standard module documented in AutoLoader, for example.) But an AUTOLOAD routine can also just emulate the routine and never define it. For example, let's pretend that a function that wasn't defined should just invoke system with those arguments. All you'd do is:

  1.     sub AUTOLOAD {
  2. 	my $program = $AUTOLOAD;
  3. 	$program =~ s/.*:://;
  4. 	system($program, @_);
  5.     }
  6.     date();
  7.     who('am', 'i');
  8.     ls('-l');

In fact, if you predeclare functions you want to call that way, you don't even need parentheses:

  1.     use subs qw(date who ls);
  2.     date;
  3.     who "am", "i";
  4.     ls -l;

A more complete example of this is the standard Shell module, which can treat undefined subroutine calls as calls to external programs.

Mechanisms are available to help modules writers split their modules into autoloadable files. See the standard AutoLoader module described in AutoLoader and in AutoSplit, the standard SelfLoader modules in SelfLoader, and the document on adding C functions to Perl code in perlxs.

Subroutine Attributes

A subroutine declaration or definition may have a list of attributes associated with it. If such an attribute list is present, it is broken up at space or colon boundaries and treated as though a use attributes had been seen. See attributes for details about what attributes are currently supported. Unlike the limitation with the obsolescent use attrs , the sub : ATTRLIST syntax works to associate the attributes with a pre-declaration, and not just with a subroutine definition.

The attributes must be valid as simple identifier names (without any punctuation other than the '_' character). They may have a parameter list appended, which is only checked for whether its parentheses ('(',')') nest properly.

Examples of valid syntax (even though the attributes are unknown):

  1.     sub fnord (&\%) : switch(10,foo(7,3))  :  expensive;
  2.     sub plugh () : Ugly('\(") :Bad;
  3.     sub xyzzy : _5x5 { ... }

Examples of invalid syntax:

  1.     sub fnord : switch(10,foo(); # ()-string not balanced
  2.     sub snoid : Ugly('(');	  # ()-string not balanced
  3.     sub xyzzy : 5x5;		  # "5x5" not a valid identifier
  4.     sub plugh : Y2::north;	  # "Y2::north" not a simple identifier
  5.     sub snurt : foo + bar;	  # "+" not a colon or space

The attribute list is passed as a list of constant strings to the code which associates them with the subroutine. In particular, the second example of valid syntax above currently looks like this in terms of how it's parsed and invoked:

  1.     use attributes __PACKAGE__, \&plugh, q[Ugly('\(")], 'Bad';

For further details on attribute lists and their manipulation, see attributes and Attribute::Handlers.

SEE ALSO

See Function Templates in perlref for more about references and closures. See perlxs if you'd like to learn about calling C subroutines from Perl. See perlembed if you'd like to learn about calling Perl subroutines from C. See perlmod to learn about bundling up your functions in separate files. See perlmodlib to learn what library modules come standard on your system. See perltoot to learn how to make object method calls.

Page index