• TUX



Perl 5 version 8.9 documentation
Recently read



perltrap - Perl traps for the unwary


The biggest trap of all is forgetting to use warnings or use the -w switch; see perllexwarn and perlrun. The second biggest trap is not making your entire program runnable under use strict . The third biggest trap is not reading the list of changes in this version of Perl; see perldelta.

Awk Traps

Accustomed awk users should take special note of the following:

  • A Perl program executes only once, not once for each input line. You can do an implicit loop with -n or -p .

  • The English module, loaded via

    1. use English;

    allows you to refer to special variables (like $/ ) with names (like $RS), as though they were in awk; see perlvar for details.

  • Semicolons are required after all simple statements in Perl (except at the end of a block). Newline is not a statement delimiter.

  • Curly brackets are required on if s and while s.

  • Variables begin with "$", "@" or "%" in Perl.

  • Arrays index from 0. Likewise string positions in substr() and index().

  • You have to decide whether your array has numeric or string indices.

  • Hash values do not spring into existence upon mere reference.

  • You have to decide whether you want to use string or numeric comparisons.

  • Reading an input line does not split it for you. You get to split it to an array yourself. And the split() operator has different arguments than awk's.

  • The current input line is normally in $_, not $0. It generally does not have the newline stripped. ($0 is the name of the program executed.) See perlvar.

  • $<digit> does not refer to fields--it refers to substrings matched by the last match pattern.

  • The print() statement does not add field and record separators unless you set $, and $\ . You can set $OFS and $ORS if you're using the English module.

  • You must open your files before you print to them.

  • The range operator is "..", not comma. The comma operator works as in C.

  • The match operator is "=~", not "~". ("~" is the one's complement operator, as in C.)

  • The exponentiation operator is "**", not "^". "^" is the XOR operator, as in C. (You know, one could get the feeling that awk is basically incompatible with C.)

  • The concatenation operator is ".", not the null string. (Using the null string would render /pat/ /pat/ unparsable, because the third slash would be interpreted as a division operator--the tokenizer is in fact slightly context sensitive for operators like "/", "?", and ">". And in fact, "." itself can be the beginning of a number.)

  • The next, exit, and continue keywords work differently.

  • The following variables work differently:

    1. Awk Perl
    2. ARGC scalar @ARGV (compare with $#ARGV)
    3. ARGV[0] $0
    5. FNR $. - something
    6. FS (whatever you like)
    7. NF $#Fld, or some such
    8. NR $.
    9. OFMT $#
    10. OFS $,
    11. ORS $\
    12. RLENGTH length($&)
    13. RS $/
    14. RSTART length($`)
    15. SUBSEP $;
  • You cannot set $RS to a pattern, only a string.

  • When in doubt, run the awk construct through a2p and see what it gives you.

C/C++ Traps

Cerebral C and C++ programmers should take note of the following:

  • Curly brackets are required on if 's and while 's.

  • You must use elsif rather than else if .

  • The break and continue keywords from C become in Perl last and next, respectively. Unlike in C, these do not work within a do { } while construct. See Loop Control in perlsyn.

  • There's no switch statement. (But it's easy to build one on the fly, see Basic BLOCKs and Switch Statements in perlsyn)

  • Variables begin with "$", "@" or "%" in Perl.

  • Comments begin with "#", not "/*" or "//". Perl may interpret C/C++ comments as division operators, unterminated regular expressions or the defined-or operator.

  • You can't take the address of anything, although a similar operator in Perl is the backslash, which creates a reference.

  • ARGV must be capitalized. $ARGV[0] is C's argv[1] , and argv[0] ends up in $0 .

  • System calls such as link(), unlink(), rename(), etc. return nonzero for success, not 0. (system(), however, returns zero for success.)

  • Signal handlers deal with signal names, not numbers. Use kill -l to find their names on your system.

Sed Traps

Seasoned sed programmers should take note of the following:

  • A Perl program executes only once, not once for each input line. You can do an implicit loop with -n or -p .

  • Backreferences in substitutions use "$" rather than "\".

  • The pattern matching metacharacters "(", ")", and "|" do not have backslashes in front.

  • The range operator is ... , rather than comma.

Shell Traps

Sharp shell programmers should take note of the following:

  • The backtick operator does variable interpolation without regard to the presence of single quotes in the command.

  • The backtick operator does no translation of the return value, unlike csh.

  • Shells (especially csh) do several levels of substitution on each command line. Perl does substitution in only certain constructs such as double quotes, backticks, angle brackets, and search patterns.

  • Shells interpret scripts a little bit at a time. Perl compiles the entire program before executing it (except for BEGIN blocks, which execute at compile time).

  • The arguments are available via @ARGV, not $1, $2, etc.

  • The environment is not automatically made available as separate scalar variables.

  • The shell's test uses "=", "!=", "<" etc for string comparisons and "-eq", "-ne", "-lt" etc for numeric comparisons. This is the reverse of Perl, which uses eq , ne , lt for string comparisons, and == , != < etc for numeric comparisons.

Perl Traps

Practicing Perl Programmers should take note of the following:

  • Remember that many operations behave differently in a list context than they do in a scalar one. See perldata for details.

  • Avoid barewords if you can, especially all lowercase ones. You can't tell by just looking at it whether a bareword is a function or a string. By using quotes on strings and parentheses on function calls, you won't ever get them confused.

  • You cannot discern from mere inspection which builtins are unary operators (like chop() and chdir()) and which are list operators (like print() and unlink()). (Unless prototyped, user-defined subroutines can only be list operators, never unary ones.) See perlop and perlsub.

  • People have a hard time remembering that some functions default to $_, or @ARGV, or whatever, but that others which you might expect to do not.

  • The <FH> construct is not the name of the filehandle, it is a readline operation on that handle. The data read is assigned to $_ only if the file read is the sole condition in a while loop:

    1. while (<FH>) { }
    2. while (defined($_ = <FH>)) { }..
    3. <FH>; # data discarded!
  • Remember not to use = when you need =~ ; these two constructs are quite different:

    1. $x = /foo/;
    2. $x =~ /foo/;
  • The do {} construct isn't a real loop that you can use loop control on.

  • Use my() for local variables whenever you can get away with it (but see perlform for where you can't). Using local() actually gives a local value to a global variable, which leaves you open to unforeseen side-effects of dynamic scoping.

  • If you localize an exported variable in a module, its exported value will not change. The local name becomes an alias to a new value but the external name is still an alias for the original.

Perl4 to Perl5 Traps

Practicing Perl4 Programmers should take note of the following Perl4-to-Perl5 specific traps.

They're crudely ordered according to the following list:

  • Discontinuance, Deprecation, and BugFix traps

    Anything that's been fixed as a perl4 bug, removed as a perl4 feature or deprecated as a perl4 feature with the intent to encourage usage of some other perl5 feature.

  • Parsing Traps

    Traps that appear to stem from the new parser.

  • Numerical Traps

    Traps having to do with numerical or mathematical operators.

  • General data type traps

    Traps involving perl standard data types.

  • Context Traps - scalar, list contexts

    Traps related to context within lists, scalar statements/declarations.

  • Precedence Traps

    Traps related to the precedence of parsing, evaluation, and execution of code.

  • General Regular Expression Traps using s///, etc.

    Traps related to the use of pattern matching.

  • Subroutine, Signal, Sorting Traps

    Traps related to the use of signals and signal handlers, general subroutines, and sorting, along with sorting subroutines.

  • OS Traps

    OS-specific traps.

  • DBM Traps

    Traps specific to the use of dbmopen(), and specific dbm implementations.

  • Unclassified Traps

    Everything else.

If you find an example of a conversion trap that is not listed here, please submit it to <> for inclusion. Also note that at least some of these can be caught with the use warnings pragma or the -w switch.

Discontinuance, Deprecation, and BugFix traps

Anything that has been discontinued, deprecated, or fixed as a bug from perl4.

  • Symbols starting with "_" no longer forced into main

    Symbols starting with "_" are no longer forced into package main, except for $_ itself (and @_ , etc.).

    1. package test;
    2. $_legacy = 1;
    3. package main;
    4. print "\$_legacy is ",$_legacy,"\n";
    5. # perl4 prints: $_legacy is 1
    6. # perl5 prints: $_legacy is
  • Double-colon valid package separator in variable name

    Double-colon is now a valid package separator in a variable name. Thus these behave differently in perl4 vs. perl5, because the packages don't exist.

    1. $a=1;$b=2;$c=3;$var=4;
    2. print "$a::$b::$c ";
    3. print "$var::abc::xyz\n";
    4. # perl4 prints: 1::2::3 4::abc::xyz
    5. # perl5 prints: 3

    Given that :: is now the preferred package delimiter, it is debatable whether this should be classed as a bug or not. (The older package delimiter, ' ,is used here)

    1. $x = 10;
    2. print "x=${'x}\n";
    3. # perl4 prints: x=10
    4. # perl5 prints: Can't find string terminator "'" anywhere before EOF

    You can avoid this problem, and remain compatible with perl4, if you always explicitly include the package name:

    1. $x = 10;
    2. print "x=${main'x}\n";

    Also see precedence traps, for parsing $: .

  • 2nd and 3rd args to splice() are now in scalar context

    The second and third arguments of splice() are now evaluated in scalar context (as the Camel says) rather than list context.

    1. sub sub1{return(0,2) } # return a 2-element list
    2. sub sub2{ return(1,2,3)} # return a 3-element list
    3. @a1 = ("a","b","c","d","e");
    4. @a2 = splice(@a1,&sub1,&sub2);
    5. print join(' ',@a2),"\n";
    6. # perl4 prints: a b
    7. # perl5 prints: c d e
  • Can't do goto into a block that is optimized away

    You can't do a goto into a block that is optimized away. Darn.

    1. goto marker1;
    2. for(1){
    3. marker1:
    4. print "Here I is!\n";
    5. }
    6. # perl4 prints: Here I is!
    7. # perl5 errors: Can't "goto" into the middle of a foreach loop
  • Can't use whitespace as variable name or quote delimiter

    It is no longer syntactically legal to use whitespace as the name of a variable, or as a delimiter for any kind of quote construct. Double darn.

    1. $a = ("foo bar");
    2. $b = q baz;
    3. print "a is $a, b is $b\n";
    4. # perl4 prints: a is foo bar, b is baz
    5. # perl5 errors: Bareword found where operator expected
  • while/if BLOCK BLOCK gone

    The archaic while/if BLOCK BLOCK syntax is no longer supported.

    1. if { 1 } {
    2. print "True!";
    3. }
    4. else {
    5. print "False!";
    6. }
    7. # perl4 prints: True!
    8. # perl5 errors: syntax error at line 1, near "if {"
  • ** binds tighter than unary minus

    The ** operator now binds more tightly than unary minus. It was documented to work this way before, but didn't.

    1. print -4**2,"\n";
    2. # perl4 prints: 16
    3. # perl5 prints: -16
  • foreach changed when iterating over a list

    The meaning of foreach{} has changed slightly when it is iterating over a list which is not an array. This used to assign the list to a temporary array, but no longer does so (for efficiency). This means that you'll now be iterating over the actual values, not over copies of the values. Modifications to the loop variable can change the original values.

    1. @list = ('ab','abc','bcd','def');
    2. foreach $var (grep(/ab/,@list)){
    3. $var = 1;
    4. }
    5. print (join(':',@list));
    6. # perl4 prints: ab:abc:bcd:def
    7. # perl5 prints: 1:1:bcd:def

    To retain Perl4 semantics you need to assign your list explicitly to a temporary array and then iterate over that. For example, you might need to change

    1. foreach $var (grep(/ab/,@list)){


    1. foreach $var (@tmp = grep(/ab/,@list)){

    Otherwise changing $var will clobber the values of @list. (This most often happens when you use $_ for the loop variable, and call subroutines in the loop that don't properly localize $_ .)

  • split with no args behavior changed

    split with no arguments now behaves like split ' ' (which doesn't return an initial null field if $_ starts with whitespace), it used to behave like split /\s+/ (which does).

    1. $_ = ' hi mom';
    2. print join(':', split);
    3. # perl4 prints: :hi:mom
    4. # perl5 prints: hi:mom
  • -e behavior fixed

    Perl 4 would ignore any text which was attached to an -e switch, always taking the code snippet from the following arg. Additionally, it would silently accept an -e switch without a following arg. Both of these behaviors have been fixed.

    1. perl -e'print "attached to -e"' 'print "separate arg"'
    2. # perl4 prints: separate arg
    3. # perl5 prints: attached to -e
    4. perl -e
    5. # perl4 prints:
    6. # perl5 dies: No code specified for -e.
  • push returns number of elements in resulting list

    In Perl 4 the return value of push was undocumented, but it was actually the last value being pushed onto the target list. In Perl 5 the return value of push is documented, but has changed, it is the number of elements in the resulting list.

    1. @x = ('existing');
    2. print push(@x, 'first new', 'second new');
    3. # perl4 prints: second new
    4. # perl5 prints: 3
  • Some error messages differ

    Some error messages will be different.

  • split() honors subroutine args

    In Perl 4, if in list context the delimiters to the first argument of split() were ?? , the result would be placed in @_ as well as being returned. Perl 5 has more respect for your subroutine arguments.

  • Bugs removed

    Some bugs may have been inadvertently removed. :-)

Parsing Traps

Perl4-to-Perl5 traps from having to do with parsing.

  • Space between . and = triggers syntax error

    Note the space between . and =

    1. $string . = "more string";
    2. print $string;
    3. # perl4 prints: more string
    4. # perl5 prints: syntax error at - line 1, near ". ="
  • Better parsing in perl 5

    Better parsing in perl 5

    1. sub foo {}
    2. &foo
    3. print("hello, world\n");
    4. # perl4 prints: hello, world
    5. # perl5 prints: syntax error
  • Function parsing

    "if it looks like a function, it is a function" rule.

    1. print
    2. ($foo == 1) ? "is one\n" : "is zero\n";
    3. # perl4 prints: is zero
    4. # perl5 warns: "Useless use of a constant in void context" if using -w
  • String interpolation of $#array differs

    String interpolation of the $#array construct differs when braces are to used around the name.

    1. @a = (1..3);
    2. print "${#a}";
    3. # perl4 prints: 2
    4. # perl5 fails with syntax error
    5. @ = (1..3);
    6. print "$#{a}";
    7. # perl4 prints: {a}
    8. # perl5 prints: 2
  • Perl guesses on map, grep followed by { if it starts BLOCK or hash ref

    When perl sees map { (or grep {), it has to guess whether the { starts a BLOCK or a hash reference. If it guesses wrong, it will report a syntax error near the } and the missing (or unexpected) comma.

    Use unary + before { on a hash reference, and unary + applied to the first thing in a BLOCK (after {), for perl to guess right all the time. (See map.)

Numerical Traps

Perl4-to-Perl5 traps having to do with numerical operators, operands, or output from same.

  • Formatted output and significant digits

    Formatted output and significant digits. In general, Perl 5 tries to be more precise. For example, on a Solaris Sparc:

    1. print 7.373504 - 0, "\n";
    2. printf "%20.18f\n", 7.373504 - 0;
    3. # Perl4 prints:
    4. 7.3750399999999996141
    5. 7.375039999999999614
    6. # Perl5 prints:
    7. 7.373504
    8. 7.375039999999999614

    Notice how the first result looks better in Perl 5.

    Your results may vary, since your floating point formatting routines and even floating point format may be slightly different.

  • Auto-increment operator over signed int limit deleted

    This specific item has been deleted. It demonstrated how the auto-increment operator would not catch when a number went over the signed int limit. Fixed in version 5.003_04. But always be wary when using large integers. If in doubt:

    1. use Math::BigInt;
  • Assignment of return values from numeric equality tests doesn't work

    Assignment of return values from numeric equality tests does not work in perl5 when the test evaluates to false (0). Logical tests now return a null, instead of 0

    1. $p = ($test == 1);
    2. print $p,"\n";
    3. # perl4 prints: 0
    4. # perl5 prints:

    Also see General Regular Expression Traps using s///, etc. for another example of this new feature...

  • Bitwise string ops

    When bitwise operators which can operate upon either numbers or strings (& | ^ ~ ) are given only strings as arguments, perl4 would treat the operands as bitstrings so long as the program contained a call to the vec() function. perl5 treats the string operands as bitstrings. (See Bitwise String Operators in perlop for more details.)

    1. $fred = "10";
    2. $barney = "12";
    3. $betty = $fred & $barney;
    4. print "$betty\n";
    5. # Uncomment the next line to change perl4's behavior
    6. # ($dummy) = vec("dummy", 0, 0);
    7. # Perl4 prints:
    8. 8
    9. # Perl5 prints:
    10. 10
    11. # If vec() is used anywhere in the program, both print:
    12. 10

General data type traps

Perl4-to-Perl5 traps involving most data-types, and their usage within certain expressions and/or context.

  • Negative array subscripts now count from the end of array

    Negative array subscripts now count from the end of the array.

    1. @a = (1, 2, 3, 4, 5);
    2. print "The third element of the array is $a[3] also expressed as $a[-2] \n";
    3. # perl4 prints: The third element of the array is 4 also expressed as
    4. # perl5 prints: The third element of the array is 4 also expressed as 4
  • Setting $#array lower now discards array elements

    Setting $#array lower now discards array elements, and makes them impossible to recover.

    1. @a = (a,b,c,d,e);
    2. print "Before: ",join('',@a);
    3. $#a =1;
    4. print ", After: ",join('',@a);
    5. $#a =3;
    6. print ", Recovered: ",join('',@a),"\n";
    7. # perl4 prints: Before: abcde, After: ab, Recovered: abcd
    8. # perl5 prints: Before: abcde, After: ab, Recovered: ab
  • Hashes get defined before use

    Hashes get defined before use

    1. local($s,@a,%h);
    2. die "scalar \$s defined" if defined($s);
    3. die "array \@a defined" if defined(@a);
    4. die "hash \%h defined" if defined(%h);
    5. # perl4 prints:
    6. # perl5 dies: hash %h defined

    Perl will now generate a warning when it sees defined(@a) and defined(%h).

  • Glob assignment from localized variable to variable

    glob assignment from variable to variable will fail if the assigned variable is localized subsequent to the assignment

    1. @a = ("This is Perl 4");
    2. *b = *a;
    3. local(@a);
    4. print @b,"\n";
    5. # perl4 prints: This is Perl 4
    6. # perl5 prints:
  • Assigning undef to glob

    Assigning undef to a glob has no effect in Perl 5. In Perl 4 it undefines the associated scalar (but may have other side effects including SEGVs). Perl 5 will also warn if undef is assigned to a typeglob. (Note that assigning undef to a typeglob is different than calling the undef function on a typeglob (undef *foo ), which has quite a few effects.

    1. $foo = "bar";
    2. *foo = undef;
    3. print $foo;
    4. # perl4 prints:
    5. # perl4 warns: "Use of uninitialized variable" if using -w
    6. # perl5 prints: bar
    7. # perl5 warns: "Undefined value assigned to typeglob" if using -w
  • Changes in unary negation (of strings)

    Changes in unary negation (of strings) This change effects both the return value and what it does to auto(magic)increment.

    1. $x = "aaa";
    2. print ++$x," : ";
    3. print -$x," : ";
    4. print ++$x,"\n";
    5. # perl4 prints: aab : -0 : 1
    6. # perl5 prints: aab : -aab : aac
  • Modifying of constants prohibited

    perl 4 lets you modify constants:

    1. $foo = "x";
    2. &mod($foo);
    3. for ($x = 0; $x < 3; $x++) {
    4. &mod("a");
    5. }
    6. sub mod {
    7. print "before: $_[0]";
    8. $_[0] = "m";
    9. print " after: $_[0]\n";
    10. }
    11. # perl4:
    12. # before: x after: m
    13. # before: a after: m
    14. # before: m after: m
    15. # before: m after: m
    16. # Perl5:
    17. # before: x after: m
    18. # Modification of a read-only value attempted at line 12.
    19. # before: a
  • defined $var behavior changed

    The behavior is slightly different for:

    1. print "$x", defined $x
    2. # perl 4: 1
    3. # perl 5: <no output, $x is not called into existence>
  • Variable Suicide

    Variable suicide behavior is more consistent under Perl 5. Perl5 exhibits the same behavior for hashes and scalars, that perl4 exhibits for only scalars.

    1. $aGlobal{ "aKey" } = "global value";
    2. print "MAIN:", $aGlobal{"aKey"}, "\n";
    3. $GlobalLevel = 0;
    4. &test( *aGlobal );
    5. sub test {
    6. local( *theArgument ) = @_;
    7. local( %aNewLocal ); # perl 4 != 5.001l,m
    8. $aNewLocal{"aKey"} = "this should never appear";
    9. print "SUB: ", $theArgument{"aKey"}, "\n";
    10. $aNewLocal{"aKey"} = "level $GlobalLevel"; # what should print
    11. $GlobalLevel++;
    12. if( $GlobalLevel<4 ) {
    13. &test( *aNewLocal );
    14. }
    15. }
    16. # Perl4:
    17. # MAIN:global value
    18. # SUB: global value
    19. # SUB: level 0
    20. # SUB: level 1
    21. # SUB: level 2
    22. # Perl5:
    23. # MAIN:global value
    24. # SUB: global value
    25. # SUB: this should never appear
    26. # SUB: this should never appear
    27. # SUB: this should never appear

Context Traps - scalar, list contexts

  • Elements of argument lists for formats evaluated in list context

    The elements of argument lists for formats are now evaluated in list context. This means you can interpolate list values now.

    1. @fmt = ("foo","bar","baz");
    2. format STDOUT=
    3. @<<<<< @||||| @>>>>>
    4. @fmt;
    5. .
    6. write;
    7. # perl4 errors: Please use commas to separate fields in file
    8. # perl5 prints: foo bar baz
  • caller() returns false value in scalar context if no caller present

    The caller() function now returns a false value in a scalar context if there is no caller. This lets library files determine if they're being required.

    1. caller() ? (print "You rang?\n") : (print "Got a 0\n");
    2. # perl4 errors: There is no caller
    3. # perl5 prints: Got a 0
  • Comma operator in scalar context gives scalar context to args

    The comma operator in a scalar context is now guaranteed to give a scalar context to its arguments.

    1. @y= ('a','b','c');
    2. $x = (1, 2, @y);
    3. print "x = $x\n";
    4. # Perl4 prints: x = c # Thinks list context interpolates list
    5. # Perl5 prints: x = 3 # Knows scalar uses length of list
  • sprintf() prototyped as ($;@)

    sprintf() is prototyped as ($;@), so its first argument is given scalar context. Thus, if passed an array, it will probably not do what you want, unlike Perl 4:

    1. @z = ('%s%s', 'foo', 'bar');
    2. $x = sprintf(@z);
    3. print $x;
    4. # perl4 prints: foobar
    5. # perl5 prints: 3

    printf() works the same as it did in Perl 4, though:

    1. @z = ('%s%s', 'foo', 'bar');
    2. printf STDOUT (@z);
    3. # perl4 prints: foobar
    4. # perl5 prints: foobar

Precedence Traps

Perl4-to-Perl5 traps involving precedence order.

Perl 4 has almost the same precedence rules as Perl 5 for the operators that they both have. Perl 4 however, seems to have had some inconsistencies that made the behavior differ from what was documented.

  • LHS vs. RHS of any assignment operator

    LHS vs. RHS of any assignment operator. LHS is evaluated first in perl4, second in perl5; this can affect the relationship between side-effects in sub-expressions.

    1. @arr = ( 'left', 'right' );
    2. $a{shift @arr} = shift @arr;
    3. print join( ' ', keys %a );
    4. # perl4 prints: left
    5. # perl5 prints: right
  • Semantic errors introduced due to precedence

    These are now semantic errors because of precedence:

    1. @list = (1,2,3,4,5);
    2. %map = ("a",1,"b",2,"c",3,"d",4);
    3. $n = shift @list + 2; # first item in list plus 2
    4. print "n is $n, ";
    5. $m = keys %map + 2; # number of items in hash plus 2
    6. print "m is $m\n";
    7. # perl4 prints: n is 3, m is 6
    8. # perl5 errors and fails to compile
  • Precedence of assignment operators same as the precedence of assignment

    The precedence of assignment operators is now the same as the precedence of assignment. Perl 4 mistakenly gave them the precedence of the associated operator. So you now must parenthesize them in expressions like

    1. /foo/ ? ($a += 2) : ($a -= 2);


    1. /foo/ ? $a += 2 : $a -= 2

    would be erroneously parsed as

    1. (/foo/ ? $a += 2 : $a) -= 2;

    On the other hand,

    1. $a += /foo/ ? 1 : 2;

    now works as a C programmer would expect.

  • open requires parentheses around filehandle
    1. open FOO || die;

    is now incorrect. You need parentheses around the filehandle. Otherwise, perl5 leaves the statement as its default precedence:

    1. open(FOO || die);
    2. # perl4 opens or dies
    3. # perl5 opens FOO, dying only if 'FOO' is false, i.e. never
  • $: precedence over $:: gone

    perl4 gives the special variable, $: precedence, where perl5 treats $:: as main package

    1. $a = "x"; print "$::a";
    2. # perl 4 prints: -:a
    3. # perl 5 prints: x
  • Precedence of file test operators documented

    perl4 had buggy precedence for the file test operators vis-a-vis the assignment operators. Thus, although the precedence table for perl4 leads one to believe -e $foo .= "q" should parse as ((-e $foo) .= "q") , it actually parses as (-e ($foo .= "q")) . In perl5, the precedence is as documented.

    1. -e $foo .= "q"
    2. # perl4 prints: no output
    3. # perl5 prints: Can't modify -e in concatenation
  • keys, each, values are regular named unary operators

    In perl4, keys(), each() and values() were special high-precedence operators that operated on a single hash, but in perl5, they are regular named unary operators. As documented, named unary operators have lower precedence than the arithmetic and concatenation operators + - ., but the perl4 variants of these operators actually bind tighter than + - .. Thus, for:

    1. %foo = 1..10;
    2. print keys %foo - 1
    3. # perl4 prints: 4
    4. # perl5 prints: Type of arg 1 to keys must be hash (not subtraction)

    The perl4 behavior was probably more useful, if less consistent.

General Regular Expression Traps using s///, etc.

All types of RE traps.

  • s'$lhs'$rhs' interpolates on either side

    s'$lhs'$rhs' now does no interpolation on either side. It used to interpolate $lhs but not $rhs. (And still does not match a literal '$' in string)

    1. $a=1;$b=2;
    2. $string = '1 2 $a $b';
    3. $string =~ s'$a'$b';
    4. print $string,"\n";
    5. # perl4 prints: $b 2 $a $b
    6. # perl5 prints: 1 2 $a $b
  • m//g attaches its state to the searched string

    m//g now attaches its state to the searched string rather than the regular expression. (Once the scope of a block is left for the sub, the state of the searched string is lost)

    1. $_ = "ababab";
    2. while(m/ab/g){
    3. &doit("blah");
    4. }
    5. sub doit{local($_) = shift; print "Got $_ "}
    6. # perl4 prints: Got blah Got blah Got blah Got blah
    7. # perl5 prints: infinite loop blah...
  • m//o used within an anonymous sub

    Currently, if you use the m//o qualifier on a regular expression within an anonymous sub, all closures generated from that anonymous sub will use the regular expression as it was compiled when it was used the very first time in any such closure. For instance, if you say

    1. sub build_match {
    2. my($left,$right) = @_;
    3. return sub { $_[0] =~ /$left stuff $right/o; };
    4. }
    5. $good = build_match('foo','bar');
    6. $bad = build_match('baz','blarch');
    7. print $good->('foo stuff bar') ? "ok\n" : "not ok\n";
    8. print $bad->('baz stuff blarch') ? "ok\n" : "not ok\n";
    9. print $bad->('foo stuff bar') ? "not ok\n" : "ok\n";

    For most builds of Perl5, this will print: ok not ok not ok

    build_match() will always return a sub which matches the contents of $left and $right as they were the first time that build_match() was called, not as they are in the current call.

  • $+ isn't set to whole match

    If no parentheses are used in a match, Perl4 sets $+ to the whole match, just like $& . Perl5 does not.

    1. "abcdef" =~ /b.*e/;
    2. print "\$+ = $+\n";
    3. # perl4 prints: bcde
    4. # perl5 prints:
  • Substitution now returns null string if it fails

    substitution now returns the null string if it fails

    1. $string = "test";
    2. $value = ($string =~ s/foo//);
    3. print $value, "\n";
    4. # perl4 prints: 0
    5. # perl5 prints:

    Also see Numerical Traps for another example of this new feature.

  • s`lhs`rhs` is now a normal substitution

    s`lhs`rhs` (using backticks) is now a normal substitution, with no backtick expansion

    1. $string = "";
    2. $string =~ s`^`hostname`;
    3. print $string, "\n";
    4. # perl4 prints: <the local hostname>
    5. # perl5 prints: hostname
  • Stricter parsing of variables in regular expressions

    Stricter parsing of variables used in regular expressions

    1. s/^([^$grpc]*$grpc[$opt$plus$rep]?)//o;
    2. # perl4: compiles w/o error
    3. # perl5: with Scalar found where operator expected ..., near "$opt$plus"

    an added component of this example, apparently from the same script, is the actual value of the s'd string after the substitution. [$opt] is a character class in perl4 and an array subscript in perl5

    1. $grpc = 'a';
    2. $opt = 'r';
    3. $_ = 'bar';
    4. s/^([^$grpc]*$grpc[$opt]?)/foo/;
    5. print;
    6. # perl4 prints: foo
    7. # perl5 prints: foobar
  • m?x? matches only once

    Under perl5, m?x? matches only once, like ?x? . Under perl4, it matched repeatedly, like /x/ or m!x!.

    1. $test = "once";
    2. sub match { $test =~ m?once?; }
    3. &match();
    4. if( &match() ) {
    5. # m?x? matches more then once
    6. print "perl4\n";
    7. } else {
    8. # m?x? matches only once
    9. print "perl5\n";
    10. }
    11. # perl4 prints: perl4
    12. # perl5 prints: perl5
  • Failed matches don't reset the match variables

    Unlike in Ruby, failed matches in Perl do not reset the match variables ($1, $2, ..., $` , ...).

Subroutine, Signal, Sorting Traps

The general group of Perl4-to-Perl5 traps having to do with Signals, Sorting, and their related subroutines, as well as general subroutine traps. Includes some OS-Specific traps.

  • Barewords that used to look like strings look like subroutine calls

    Barewords that used to look like strings to Perl will now look like subroutine calls if a subroutine by that name is defined before the compiler sees them.

    1. sub SeeYa { warn"Hasta la vista, baby!" }
    2. $SIG{'TERM'} = SeeYa;
    3. print "SIGTERM is now $SIG{'TERM'}\n";
    4. # perl4 prints: SIGTERM is now main'SeeYa
    5. # perl5 prints: SIGTERM is now main::1 (and warns "Hasta la vista, baby!")

    Use -w to catch this one

  • Reverse is no longer allowed as the name of a sort subroutine

    reverse is no longer allowed as the name of a sort subroutine.

    1. sub reverse{ print "yup "; $a <=> $b }
    2. print sort reverse (2,1,3);
    3. # perl4 prints: yup yup 123
    4. # perl5 prints: 123
    5. # perl5 warns (if using -w): Ambiguous call resolved as CORE::reverse()
  • warn() won't let you specify a filehandle.

    Although it _always_ printed to STDERR, warn() would let you specify a filehandle in perl4. With perl5 it does not.

    1. warn STDERR "Foo!";
    2. # perl4 prints: Foo!
    3. # perl5 prints: String found where operator expected

OS Traps

  • SysV resets signal handler correctly

    Under HPUX, and some other SysV OSes, one had to reset any signal handler, within the signal handler function, each time a signal was handled with perl4. With perl5, the reset is now done correctly. Any code relying on the handler _not_ being reset will have to be reworked.

    Since version 5.002, Perl uses sigaction() under SysV.

    1. sub gotit {
    2. print "Got @_... ";
    3. }
    4. $SIG{'INT'} = 'gotit';
    5. $| = 1;
    6. $pid = fork;
    7. if ($pid) {
    8. kill('INT', $pid);
    9. sleep(1);
    10. kill('INT', $pid);
    11. } else {
    12. while (1) {sleep(10);}
    13. }
    14. # perl4 (HPUX) prints: Got INT...
    15. # perl5 (HPUX) prints: Got INT... Got INT...
  • SysV seek() appends correctly

    Under SysV OSes, seek() on a file opened to append >> now does the right thing w.r.t. the fopen() manpage. e.g., - When a file is opened for append, it is impossible to overwrite information already in the file.

    1. open(TEST,">>seek.test");
    2. $start = tell TEST;
    3. foreach(1 .. 9){
    4. print TEST "$_ ";
    5. }
    6. $end = tell TEST;
    7. seek(TEST,$start,0);
    8. print TEST "18 characters here";
    9. # perl4 (solaris) seek.test has: 18 characters here
    10. # perl5 (solaris) seek.test has: 1 2 3 4 5 6 7 8 9 18 characters here

Interpolation Traps

Perl4-to-Perl5 traps having to do with how things get interpolated within certain expressions, statements, contexts, or whatever.

  • @ always interpolates an array in double-quotish strings

    @ now always interpolates an array in double-quotish strings.

    1. print "To:\n";
    2. # perl4 prints:
    3. # perl < 5.6.1, error : In string, @somewhere now must be written as \@somewhere
    4. # perl >= 5.6.1, warning : Possible unintended interpolation of @somewhere in string
  • Double-quoted strings may no longer end with an unescaped $

    Double-quoted strings may no longer end with an unescaped $.

    1. $foo = "foo$";
    2. print "foo is $foo\n";
    3. # perl4 prints: foo is foo$
    4. # perl5 errors: Final $ should be \$ or $name

    Note: perl5 DOES NOT error on the terminating @ in $bar

  • Arbitrary expressions are evaluated inside braces within double quotes

    Perl now sometimes evaluates arbitrary expressions inside braces that occur within double quotes (usually when the opening brace is preceded by $ or @ ).

    1. @www = "buz";
    2. $foo = "foo";
    3. $bar = "bar";
    4. sub foo { return "bar" };
    5. print "|@{w.w.w}|${main'foo}|";
    6. # perl4 prints: |@{w.w.w}|foo|
    7. # perl5 prints: |buz|bar|

    Note that you can use strict; to ward off such trappiness under perl5.

  • $$x now tries to dereference $x

    The construct "this is $$x" used to interpolate the pid at that point, but now tries to dereference $x. $$ by itself still works fine, however.

    1. $s = "a reference";
    2. $x = *s;
    3. print "this is $$x\n";
    4. # perl4 prints: this is XXXx (XXX is the current pid)
    5. # perl5 prints: this is a reference
  • Creation of hashes on the fly with eval "EXPR" requires protection

    Creation of hashes on the fly with eval "EXPR" now requires either both $ 's to be protected in the specification of the hash name, or both curlies to be protected. If both curlies are protected, the result will be compatible with perl4 and perl5. This is a very common practice, and should be changed to use the block form of eval{} if possible.

    1. $hashname = "foobar";
    2. $key = "baz";
    3. $value = 1234;
    4. eval "\$$hashname{'$key'} = q|$value|";
    5. (defined($foobar{'baz'})) ? (print "Yup") : (print "Nope");
    6. # perl4 prints: Yup
    7. # perl5 prints: Nope


    1. eval "\$$hashname{'$key'} = q|$value|";


    1. eval "\$\$hashname{'$key'} = q|$value|";

    causes the following result:

    1. # perl4 prints: Nope
    2. # perl5 prints: Yup

    or, changing to

    1. eval "\$$hashname\{'$key'\} = q|$value|";

    causes the following result:

    1. # perl4 prints: Yup
    2. # perl5 prints: Yup
    3. # and is compatible for both versions
  • Bugs in earlier perl versions

    perl4 programs which unconsciously rely on the bugs in earlier perl versions.

    1. perl -e '$bar=q/not/; print "This is $foo{$bar} perl5"'
    2. # perl4 prints: This is not perl5
    3. # perl5 prints: This is perl5
  • Array and hash brackets during interpolation

    You also have to be careful about array and hash brackets during interpolation.

    1. print "$foo["
    2. perl 4 prints: [
    3. perl 5 prints: syntax error
    4. print "$foo{"
    5. perl 4 prints: {
    6. perl 5 prints: syntax error

    Perl 5 is expecting to find an index or key name following the respective brackets, as well as an ending bracket of the appropriate type. In order to mimic the behavior of Perl 4, you must escape the bracket like so.

    1. print "$foo\[";
    2. print "$foo\{";
  • Interpolation of \$$foo{bar}

    Similarly, watch out for: \$$foo{bar}

    1. $foo = "baz";
    2. print "\$$foo{bar}\n";
    3. # perl4 prints: $baz{bar}
    4. # perl5 prints: $

    Perl 5 is looking for $foo{bar} which doesn't exist, but perl 4 is happy just to expand $foo to "baz" by itself. Watch out for this especially in eval's.

  • qq() string passed to eval will not find string terminator

    qq() string passed to eval

    1. eval qq(
    2. foreach \$y (keys %\$x\) {
    3. \$count++;
    4. }
    5. );
    6. # perl4 runs this ok
    7. # perl5 prints: Can't find string terminator ")"

DBM Traps

General DBM traps.

  • Perl5 must have been linked with same dbm/ndbm as the default for dbmopen()

    Existing dbm databases created under perl4 (or any other dbm/ndbm tool) may cause the same script, run under perl5, to fail. The build of perl5 must have been linked with the same dbm/ndbm as the default for dbmopen() to function properly without tie'ing to an extension dbm implementation.

    1. dbmopen (%dbm, "file", undef);
    2. print "ok\n";
    3. # perl4 prints: ok
    4. # perl5 prints: ok (IFF linked with -ldbm or -lndbm)
  • DBM exceeding limit on the key/value size will cause perl5 to exit immediately

    Existing dbm databases created under perl4 (or any other dbm/ndbm tool) may cause the same script, run under perl5, to fail. The error generated when exceeding the limit on the key/value size will cause perl5 to exit immediately.

    1. dbmopen(DB, "testdb",0600) || die "couldn't open db! $!";
    2. $DB{'trap'} = "x" x 1024; # value too large for most dbm/ndbm
    3. print "YUP\n";
    4. # perl4 prints:
    5. dbm store returned -1, errno 28, key "trap" at - line 3.
    6. YUP
    7. # perl5 prints:
    8. dbm store returned -1, errno 28, key "trap" at - line 3.

Unclassified Traps

Everything else.

  • require/do trap using returned value

    If the file has:

    1. sub foo {
    2. $rc = do "./";
    3. return 8;
    4. }
    5. print &foo, "\n";

    And the file has the following single line:

    1. return 3;

    Running gives the following:

    1. # perl 4 prints: 3 (aborts the subroutine early)
    2. # perl 5 prints: 8

    Same behavior if you replace do with require.

  • split on empty string with LIMIT specified
    1. $string = '';
    2. @list = split(/foo/, $string, 2)

    Perl4 returns a one element list containing the empty string but Perl5 returns an empty list.

As always, if any of these are ever officially declared as bugs, they'll be fixed and removed.